Załóżmy taką sytuację, że musisz zliczyć ilość wszystkich wystąpień wielkiej litery U w zakresie komórek. To zadanie jest relatywnie proste 😉

Porada 287 - Jak policzyć ilość wielkiej litery U w komórkach 02

Zacznijmy od tego, że będzie nam potrzebna funkcja PODSTAW, która w danym ciągu tekstowym (nawet w zakresie komórek) zamieni dany ciąg tekstowy na inny ciąg tekstowy. W naszym przykładzie ważne jest to, że rozróżnia ona wielkość liter, czyli jeśli każemy jej zmienić wielką literę U, to podmieni tylko ją, a małej litery u nie ruszy. W naszej sytuacji, będziemy chcieli usunąć literę/ciąg, więc będziemy chcieli ją zamienić na pusty ciąg tekstowy (dwa podwójne cudzysłowy ) np:

=PODSTAW(B2;"U";"")

Ale zanim będziemy podstawiać litery, musimy najpierw policzyć długość wszystkich ciągów w naszym zakresie komórek. Wystarczy, że skorzystamy z funkcji po tym zakresie. Excel policzy nam długość ciągów tekstowych w poszczególnych komórkach:

=DŁ(A2:B10) -> {3\3;2\3;3\2;3\2;3\2;3\4;3\3;3\3;3\3}

Porada 287 - Jak policzyć ilość wielkiej litery U w komórkach 02

Tylko zanim te wartości zsumujemy będziemy chcieli odjąć od nich długość ciągów tekstowych z usuniętą wielką literą U.

=DŁ(A2:B10)-DŁ(PODSTAW(A2:B10;"U";"")) -> {0\1;1\1;0\1;2\0;0\0;0\2;1\1;0\1;0\1}

Porada 287 - Jak policzyć ilość wielkiej litery U w komórkach 03

Teraz wystarczy zsumować wynikową tablicę wartości. Żebyś nie musiał zatwierdzać formuły jako tablicową kombinacją klawiszy Ctrl + Shift + Enter, to wstawimy naszą formułę do funkcji SUMA.ILOCZYNÓW i już mamy interesujący nas wynik

=SUMA.ILOCZYNÓW(DŁ(A2:B10)-DŁ(PODSTAW(A2:B10;"U";"")))

Porada 287 - Jak policzyć ilość wielkiej litery U w komórkach 04

Żeby w analogiczny sposób obliczyć ilość wystąpień ciągu tekstowego, musisz tylko podmieniać zmieniany tekst i podzielić formułę przez długość tego tekstu np:

=SUMA.ILOCZYNÓW(DŁ(A2:B10)-DŁ(PODSTAW(A2:B10;"WU";"")))/DŁ("WU")

Porada 287 - Jak policzyć ilość wielkiej litery U w komórkach 05

Pozdrawiam
Adam Kopeć
Miłośnik Excela