Sumowanie sprzedaży po dniu tygodnia

Jak zsumować sprzedaż po wybranym dniu tygodnia?

W poszczególnych dniach tygodnia masz różną sprzedaż. Chcesz wiedzieć jak zsumować wartość sprzedaży dla konkretnego dnia.

Sumowanie sprzedaży po dniu tygodnia — sztuczki #21

Najpierw potrzebne są daty. Ich odpowiednie formatowanie

dddd, mmmm dd, rrrr

zapewni Ci, że będziesz widział wszystkie potrzebne informacje wpisując bardzo mało. Powyższe formatowanie zapewni Ci, że każda data będzie pokazywana w komórce w koncepcji:

nazwa dnia, nazwa miesiąca numer dnia, rok

Tabela z sformatowanymi odpowiednio datami

Jednak wyświetlany "piątek" jest wynikiem formatowania i ciężko byłoby wyciągać nazwę dnia, nawet jakby byłby to tekst. O wiele proście pracować na datach (liczbach) i skorzystać z funkcji TEKST z odpowiednimi argumentami:

TEKST($A$2:$A$18;"ddd")

1 argument ($A$2:$A$18) to zakres gdzie są przechowywane daty,
2 argument ("ddd") mówi Excel ma wyciągnąć z podanych liczb tylko nazwę skróconą dnia.

Nazwa skrócone dni tygodnia zawiera tabela poniżej:

Tabela ze skróconymi nazwami dni tygodnia

Teraz należy przyrównać wynik funkcji TEKST do kryterium. Uzyskasz w ten sposób tablicę z wartością PRAWDA wtedy gdy kryterium będzie spełnione ({FAŁSZ;PRAWDA;FAŁSZ;FAŁSZ;PRAWDA;FAŁSZ;FAŁSZ;FAŁSZ})

Kolejnym krokiem będzie wykorzystanie funkcji SUMA.ILOCZYNÓW i dołożenie kolejnego czynnika jakim jest zakres z wartościami sprzedaży w poszczególne dni

=SUMA.ILOCZYNÓW(TEKST($A$2:$A$18;"ddd")=E2;$B$2:$B$18)

ponieważ jednak funkcja SUMA.ILOCZYNÓW nie rozumie wartości PRAWDA i FAŁSZ, żeby otrzymać prawidłowe wartości, trzeba jeszcze wynik porównania funkcji TEKST zamienić na wartości liczbowe — trzeba na tekście wykonać operację matematyczną (dodać 0, przemnożyć przez 1, wykorzystać podwójny znak minus –), ponieważ w Excelu z tych operacji najszybciej działa podwójna negacja (2 znaki minus),

Wartości PRAWDA i FAŁSZ zamienione na 0 i 1 w formule

dlatego ją wykorzystamy:

=SUMA.ILOCZYNÓW(–(TEKST($A$2:$A$18;"ddd")=E2);$B$2:$B$18)

Wynik obliczenia dla wykorzystanej funkcji TEKST w formule

Pamiętaj tylko o kolejności operacji arytmetycznych, znak minus działa dużo wcześniej od porównania (znaku =), dlatego trzeba dodać nawiasy.

Jeśli chcesz wykorzystać inne nazwy dni od tych standardowych, to trzeba do tego podejść w inny sposób.

Tabela z innymi nazwami dni tygodnia i przypisanymi im numerami

Trzeba wykorzystać funkcję DZIEŃ.TYG i WYSZUKAJ.PIONOWO orz tablicę przechowującą numery dni tygodnia oraz odpowiadające im nazwy dni tygodnia.

DZIEŃ.TYG($A$2:$A$18)=WYSZUKAJ.PIONOWO($E$5;$E$7:$F$13;2;0)

Tu też należy to włożyć w funkcję SUMA.ILOCZYNÓW dodać 2 minusy w odpowiednim miejscu i 2 czynnik jakim są wartości sprzedaży:

=SUMA.ILOCZYNÓW(–(DZIEŃ.TYG($A$2:$A$18)=WYSZUKAJ.PIONOWO($E$5;$E$7:$F$13;2;0));$B$2:$B$18)

Wynik obliczenia dla wykorzystanej funkcji DZIEŃ.TYG i odwołaniu do tabeli nazw dni tygodnia

Przy tej formule można podstawić w miejsce zakresu tabeli z numerami dni tygodnia i przypisanymi ich nazwami wartości stałe:

{"N"\1;"Pon"\2;"Wt"\3;"Śr"\4;"Czw"\5;"Pt"\6;"So"\7}

Najprościej to zrobisz zaznaczając zakres podczas edycji formuły i naciskając klawisz F9 i zatwierdzisz wynik Enterem.

=SUMA.ILOCZYNÓW(–(DZIEŃ.TYG($A$2:$A$18)=WYSZUKAJ.PIONOWO($E$5;{"N"\1;"Pon"\2;"Wt"\3;"Śr"\4;"Czw"\5;"Pt"\6;"So"\7};2;0));$B$2:$B$18)

Podmienione w formule odwołanie do zakresu z nazwami i liczbami dnia tygodnia na tablicę wartości

P.S.

Wpis na podstawie Excel Magic Trick 997

Jeśli chcesz dowiedzieć się więcej na temat Excela lub nie wiesz jak coś zrobić do mnie o tym w komentarzu pod spodem albo napisz do mnie bezpośrednio, ja w miarę możliwości odpowiem na Twoje pytanie.