Excel - kurs online - oferta dla każdego

Nie znasz dobrze obsługi Excela? A może nie znasz jej wcale? Doskonale wiem, że w dzisiejszych czasach i realiach, znajomość tego programu jest nie tylko niezbędna, ale przede wszystkim korzystna dla Ciebie samego. Moje szkolenie z Excela online pokaże Ci, że arkusz kalkulacyjny nie jest wcale Twoim wrogiem, a sprzymierzeńcem w porządkowaniu i analizie danych - nie tylko liczbowych. Stworzyłem kurs Excel online na każdym poziomie, zarówno dla osób początkujących, średniozaawansowanych, jak i zaawansowanych. Znajdziesz u mnie także szkolenie z Excela online dedykowane specjalnie przedsiębiorcom. Każdy kurs zawiera starannie wyselekcjonowany zakres wiedzy i zagadnień, które odpowiadają na ściśle sprecyzowane potrzeby jego użytkowników.


Excel - kurs online. Dlaczego warto?

Zastanawiasz się, czy Excel i kurs online to dobre połączenie? Czy taka forma nauki pracy z arkuszem kalkulacyjnym może być efektywna? Pozwól, że rozwieję Twoje wątpliwości.

Od lat z powodzeniem zajmuję się dzieleniem swoją wiedzą zdalnie. Ta forma nauki, szczególnie w ostatnim czasie, mocno zyskała na popularności, a jej techniki znacząco się rozwinęły. Abyś mógł biegle posługiwać się programem Excel, każdy swój kurs zaprojektowałem z ogromną starannością i w oparciu o zasady metodyki nauczania na odległość.

Jednak szkolenie z Excela online, to przede wszystkim ogromna wygoda dla Ciebie, ponieważ nie musisz wychodzić z domu, możesz uczyć się wraz ze mną z dowolnego miejsca i w wybranym przez siebie czasie. Dodatkowo każdy mój kurs Excela online zawiera materiały dydaktyczne dostępne dla Ciebie już po zakończeniu szkolenia. Krótkie nagrania filmowe, prezentujące różnego rodzaju działania w arkuszu kalkulacyjnym, które w dowolnej chwili możesz zatrzymać, odtworzyć ponownie, by jeszcze raz przeanalizować i utrwalić wiedzę, to doskonały sposób, by opanować Excel. Kurs online to nie tylko wygoda, to także oszczędność Twojego i mojego czasu - zamiast dojeżdżać w umówione miejsce, możemy poświęcić więcej chwil na ćwiczenia i praktykę.

Jak wyciągnąć liczbę z początku lub końca tekstu alternatywna formuła — porada #297

Bill Szysz pod poradą 294 napisał jeszcze jedną ciekawą formułę na wyciąganie liczb z początku lub końca tekstu. Ważne jest, że formuła, którą zobaczymy wyciąga liczby, czyli nie zwróci wiodących zer. Za to jest prostą formułą w porównaniu do tych, które stosowaliśmy.

Porada 297 - Jak wyciągnąć liczbę z początku lub końca tekstu (alternatywna formuła) 01

Będziemy musieli wyciągać coraz dłuższe ciągi z naszego tekstu odpowiednio z prawej strony (od końca – funkcja PRAWY) lub z lewej strony (od początku – funkcja LEWY). Zwiększającą się długość zapewnimy sobie za pomocą funkcji WIERSZ, która będzie wskazywała na zablokowany zakres – załóżmy, że od komórki A1 do A17, ale śmiało może przedłużyć ten zakres jeśli masz dłuższe teksty. Ważne, że zakres musi zaczynać się od komórki A1 (pierwszego wiersza) i być zablokowanym, żeby się nie przesuwał. 

=PRAWY(A2;WIERSZ($A$1:$A$17))

Porada 297 - Jak wyciągnąć liczbę z początku lub końca tekstu (alternatywna formuła) 02

Śmiało możesz zaznaczyć więcej wierszy nisz masz w tekście, bo w takiej sytuacji funkcja PRAWY (i analogicznie LEWY) wyciągają cały tekst.

={"5";"35";" 35";"a 35";"ka 35";"nka 35";"enka 35";"ienka 35";"kienka 35";"ukienka 35";"Sukienka 35";"Sukienka 35";"Sukienka 35";"Sukienka 35";"Sukienka 35";"Sukienka 35";"Sukienka 35"}

Wartości zwracane przez funkcje tekstowe są traktowane jako tekst, więc musimy je przekonwertować na liczby. Z wcześniejszych porad znamy już tą sztuczkę – to podwójna negacja – dwa znaki minus. Jeśli dany tekst da się przekonwertować na liczbę to Excel to zrobi. Jeśli jest to niemożliwe, to będzie zwracał błąd:

={5;35;35;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!;#ARG!}

W takiej tablicy wystarczy znaleźć największą liczbę. Można to zrobić za pomocą funkcji WYSZUKAJ i szukania dużej liczby np.: 9 do 99 potęgi:

=WYSZUKAJ(9^99;–PRAWY(A2;WIERSZ($A$1:$A$17)))

Porada 297 - Jak wyciągnąć liczbę z początku lub końca tekstu (alternatywna formuła) 03

To już cała formuła ? Analogicznie przy szukaniu liczb od początku tekstu musimy zamienić tylko funkcję PRAWY na LEWY i gotowe.

=WYSZUKAJ(9^99;–LEWY(D2;WIERSZ($A$1:$A$17)))

Na koniec trzeba powiedzieć o jeszcze jednym ograniczeniu tego sposobu – jeśli Excel jest wstanie zamienić jakiś zapis na liczbę (datę) za pomocą podwójnej negacji to to zrobi. Np. tekst „23 Czekolada” powinien zwracać poprawnie 23, ale wynik formuły jest całkiem inny:

Porada 297 - Jak wyciągnąć liczbę z początku lub końca tekstu (alternatywna formuła) 04

Wynika to, że w kolejnych wyciąganych tekstach pojawia się zapis „23 Cze”, który Excel tłumaczy sobie jako 23 czerwca bieżącego roku i zamienia na odpowiednią reprezentację liczbową. Stąd taki niespodziewany wynik formuły.

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Jak wyciągnąć liczbę z początku lub końca tekstu — porada #294

Chcemy wyciągnąć liczbę z początku lub końca tekstu. Najpierw zajmiemy się pisaniem formuły do wyciągnięcia liczby z końca tekstu.

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 01

Jednym ze sposobów jest zaczęcie od znalezienie pozycji kolejnych cyfr. Możemy wykorzystać funkcję SZUKAJ.TEKST lub ZNAJDŹ. Obie znajdują pozycję szukanego tekstu (w naszym przykładzie liczby) w przeszukiwanym tekście, ale funkcja SZUKAJ.TEKST nie zwraca uwagi na wielkość liter, a funkcja ZNAJDŹ zwraca uwagę na wielkość liter. Ponieważ szukamy cyfr skorzystamy z funkcji, która ma krótszą nazwę.

Dalej ważne jest, że chcemy znaleźć pierwszą pozycję każdej cyfry. Żeby to zrobić musimy wpisać wszystkie cyfry w nawiasach klamrowych oddzielone slashami

{0\1\2\3\4\5\6\7\8\9}

Można sobie ułatwić życie i stworzyć serię cyfr w wierszu, odwołać się do niej, a następnie zaznaczyć całe odwołanie do tej serii i nacisnąć klawisz F9 – wtedy Excel zamiast odwołania wstawi potrzebną tablicę.

To, że zamiast odwołania do komórek skorzystamy z tablicy wpisanej na stałe (hardkodowej) pozwoli nam zatwierdzać formułę zwyczajnie, a nie jako formułę tablicową (za pomocą kombinacji klawiszy Ctrl + Shift + Enter).

=ZNAJDŹ({0\1\2\3\4\5\6\7\8\9}; A2)

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 02

Jednak przy wyszukiwaniu poszczególnych cyfr pojawią się błędy, gdy danej cyfry nie ma w przeszukiwanym tekście.

{10\#ARG!\#ARG!\#ARG!\#ARG!\11\#ARG!\#ARG!\#ARG!\#ARG!}

Obsługa błędów może być kłopotliwa, dlatego skorzystamy ze sztuczki, która ułatwi nam zadanie – do oryginalnego tekstu dołożymy na koniec ciąg wszystkich cyfr.

=ZNAJDŹ({0\1\2\3\4\5\6\7\8\9}; A2&"0123456789")

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 03

Dzięki temu zawsze znajdziemy każdą cyfrę, co najwyżej poza długością przeszukiwanego tekstu.

={10\13\14\15\16\11\18\19\20\21}

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 04

Ponieważ nas interesuje pierwsze wystąpienie jakiejkolwiek cyfry dlatego naszą dotychczasową formułę wstawimy do funkcji MIN.

=MIN(ZNAJDŹ({0\1\2\3\4\5\6\7\8\9}; A2&"0123456789"))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 05

Teraz żeby odnaleźć ile znaków chcemy wyciągnąć z prawej strony tekstu (funkcja PRAWY) wystarczy znalezioną pozycję pierwszej cyfry odjąć od długości całego tekstu i dodać korygującą jedynkę.

=PRAWY(A2;DŁ(A2)-MIN(ZNAJDŹ({0\1\2\3\4\5\6\7\8\9}; A2&"0123456789"))+1)

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 06

Jak wyciągnęliśmy liczbę z końca tekstu to możemy teraz w łatwy sposób wyciągnąć sam tekst odejmując od długości całego tekstu długość liczby.

=LEWY(A2;DŁ(A2)-DŁ(C2))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 07

Teraz zajmiemy się przypadkiem, gdy nasza liczba jest na początku tekstu. Musimy podejść do tego inaczej. Zaczniemy od tego, że usuniemy z tekstu po kolei każdą cyfrę za pomocą funkcji PODSTAW i pustego ciągu znaków:

=PODSTAW(I2;{0\1\2\3\4\5\6\7\8\9};"")

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 08

Uzyskamy wtedy dziesięć tekstów, w których nie będą się znajdować poszczególne cyfry, czyli w większości będzie to cały tekst, bo danej cyfry już na początku nie będzie w tekście.

={"5 Czekoladki"\"05 Czekoladki"\"05 Czekoladki"\"05 Czekoladki"\"05 Czekoladki"\"0 Czekoladki"\"05 Czekoladki"\"05 Czekoladki"\"05 Czekoladki"\"05 Czekoladki"}

Tylko, że nam nie są potrzebne same teksty, tylko ich długość, czyli naszą formułę wstawiamy do funkcji . Znowu ponieważ wpisaliśmy na stałe tablicę cyfr (hardkodowanie) nie musimy zatwierdzać naszej formuły jako formuły tablicowej.

=DŁ(PODSTAW(I2;{0\1\2\3\4\5\6\7\8\9};""))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 09

Dzięki temu uzyskamy długość tekstu po usunięciu każdej kolejnej cyfry.

={12\13\13\13\13\12\13\13\13\13}

Czasami widać różnicę, do oryginalnej długości tekstu i właśnie tej różnicy szukamy. Wystarczy, że od długości oryginalnego tekstu odejmiemy te poszczególne długości.

=DŁ(I2)-DŁ(PODSTAW(I2;{0\1\2\3\4\5\6\7\8\9};""))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 10

Wynikiem będzie tablica różnic

={1\0\0\0\0\1\0\0\0\0}

Zostaje nam ją tylko zsumować i mamy długość całej liczby, która znajduje się na początku tekstu.

=SUMA(DŁ(I2)-DŁ(PODSTAW(I2;{0\1\2\3\4\5\6\7\8\9};"")))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 11

Teraz wystarczy, że tą sumę wstawimy do funkcji LEWY i udało nam się wyciągnąć szukaną liczbę na początku tekstu.

=LEWY(I2;SUMA(DŁ(I2)-DŁ(PODSTAW(I2;{0\1\2\3\4\5\6\7\8\9};""))))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 12

Jak już wyciągnęliśmy liczbę, to z łatwością wyciągnąć możemy tekst, ewentualnie usuwając zbędne spacje:

=USUŃ.ZBĘDNE.ODSTĘPY(PRAWY(I2;DŁ(I2)-DŁ(J2)))

Porada 294 - Jak wyciągnąć liczbę z początka lub końca tekstu 13

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Wykres przedziału czynszu od do w różnych miejscowościach — widzowie #24

Jak stworzyć wykres pokazujący przedział od maksimum do minimum?


Wykres przedziału czynszu od do w różnych miejscowościach — widzowie #24

Wykres przedziału czynszu od do w różnych miejscowościach - widzowie #24

Dostałem zapytanie jak stworzyć wykres, który przedstawiałby przedział wartości czynszu od do w różnych miejscowościach.

Znalazłem bardzo proste rozwiązanie, które dobrze się prezentowało, ale najpierw trzeba było przygotować dane, bo format wejściowy wyglądał tak:

3,60–5,30

czyli min i max oddzielone myślnikiem.

Czyli trzeba było z tekstu (wyrównany do lewej) wyciągnąć wartości liczbowe.

Minimum wyciągnąłem formułą:

=LEWY(B3;ZNAJDŹ("-";B3)-1)+0

Czyli wyciągnąłem wszystkie znaki od lewej przed myślnikiem, a następnie dodałem zero, by zamienić tekst na liczbę.

Bardzo podobnie wyciągnąłem maksimum:

=PRAWY(B3;DŁ(B3)-ZNAJDŹ("-";B3))+0

Tym razem wyciągałem wszystkie znaki od prawej po myślniku i dodałem zero by zamienić tekst na liczbę.

Teraz wystarczyło zaznaczyć dane liczbowe z nagłówkami i wstawić wykres liniowy najlepiej ze znacznikami.

Kolejnym krokiem było dodanie linii (karta Narzędzia wykresów — Układ — opcja linie maks-min).

Po tym zostały tylko czynności upiększające — usunięcie legendy oraz linii z serii, oraz dopracowanie kolorystyki, wielkości znaczników i linii maks-min.

P.S.

Jeśli chcesz dowiedzieć się więcej na temat Excela lub nie wiesz jak coś zrobić do mnie o tym w komentarzu pod spodem albo napisz do mnie bezpośrednio, ja w miarę możliwości odpowiem na Twoje pytanie.

Excel i Adam - kontakt

Bezpośredni odnośnik do filmu na youtube — Wykres przedziału czynszu od do w różnych miejscowościach — widzowie #24

Przez jaki obiektyw patrzysz kiedy rozwiązujesz problemy w Excelu — sztuczki #44

Jak różne podejście do problemu może dawać różne rozwiązania?


Excel — Przez jaki obiektyw patrzysz kiedy rozwiązujesz problemy w Excelu — sztuczki #44

Dyskusja o tym, jak podchodzimy do rozwiązywania problemów w Excelu. Zależy od tego, jak widzimy problem. Wiem, że wydaje się to oczywiste, ale w tym filmie zobaczyć konkretny przykład, jak dwie osoby zobaczyłem ten sam problem zupełnie inaczej.

Zobacz rozwiązania excelisfun i circledchicken problemu jak wygenerować następny kod z kolumny wypełnionej kodami składającymi się z litery wiodącej oraz 3 następujących po niej cyfr:

      1. "Wyszukaj ostatni" — koncepcyjne podejście excelisfun wykorzystujące funkcje SZUKAJ.TEKST, WYSZUKAJ, PRAWY i TEKST z formułą tablicową.
      2. "Kolumna wypełniona 4 znakowym kodem" koncepcyjne podejście circledchicken za pomocą LEWY, PRAWY, JEŻELI, MAX i TEKST z formułą tablicową.

Mr Excel Forum post:
https://www.mrexcel.com/forum/excel-questions/713666-next-customer-code.html#post3518687

P.S.

Wpis na podstawie Excel Magic Trick 1020

Jeśli chcesz dowiedzieć się więcej na temat Excela lub nie wiesz jak coś zrobić do mnie o tym w komentarzu pod spodem albo napisz do mnie bezpośrednio, ja w miarę możliwości odpowiem na Twoje pytanie.

Excel i Adam - kontakt

Bezpośredni odnośnik do filmu na youtube — Excel — Przez jaki obiektyw patrzysz kiedy rozwiązujesz problemy w Excelu — sztuczki #44

Znajdź największą liczbę za fragmentem tekstu — sztuczki #25

Jak znaleźć największą wartość znajdującą się po wybranym fragmencie tekstu?

Jeśli chcesz znaleźć komórkę gdzie po wyszukiwanym fragmencie tekstu jest największa liczba potrzebujesz wykonać kilka kroków. 


Znajdź największą liczbę za fragmentem tekstu — sztuczki #25

Na czerwono szukany tekst, a na zielono wynik końcowego wyszukania

Na czerwono szukany tekst, a na zielono wynik końcowego wyszukania

Najpierw trzeba znaleźć wszystkie wystąpienia szukanego fragmentu tekstu — funkcja SZUKAJ.TEKST, niestety zwraca ona błąd #ARG! jeśli nie znajdzie fragmentu. W naszych obliczeniach będzie to stanowić problem, więc należy dodatkowo wykorzystać funkcję CZY.LICZBA, żeby zamienić wyniki na wartości logiczne PRAWDA (gdy znalazł fragment) i FAŁSZ (gdy nie znalazł)

=CZY.LICZBA(SZUKAJ.TEKST(D2;A2:A10))

W naszym przykładzie mamy zawsze liczbę 2 cyfrową po prawej stronie, więc wyciągamy ją funkcją 

=PRAWY(A2:A10;2)

Wynik działania funkcji PRAWY - znajduje liczby i traktuje je jak tekst

Wynik działania funkcji PRAWY — znajduje liczby i traktuje je jak tekst

Teraz wystarczy zwykłe mnożenie matematyczne, by zamienić wartości logiczne i liczby traktowane jako tekst, na liczby tam gdzie są fragmenty szukanego tekstu i zera gdzie nie ma.

=CZY.LICZBA(SZUKAJ.TEKST(D2;A2:A10))*PRAWY(A2:A10;2)

Wynik działania przemnożenia funkcji PRAWY i SZUKAJ.TEKST

Wynik działania przemnożenia funkcji PRAWY i SZUKAJ.TEKST

Następnie wyciągamy maksymalną liczbę 

=MAX(CZY.LICZBA(SZUKAJ.TEKST(D2;A2:A10))*PRAWY(A2:A10;2))

a później szukamy jej pozycji, czyli funkcja PODAJ.POZYCJĘ wykorzystująca jeszcze raz wcześniejsze obliczenia i pamiętając, że szukamy dokładnego porównania (zero jako ostatni argument):

=PODAJ.POZYCJĘ(MAX(CZY.LICZBA(SZUKAJ.TEKST(D2;A2:A10))*PRAWY(A2:A10;2));SZUKAJ.TEKST(D2;A2:A10)*PRAWY(A2:A10;2);0)

teraz już można wyciągnąć szukaną wartość za pomocą formuły

=INDEKS(B2:B10;PODAJ.POZYCJĘ(MAX(CZY.LICZBA(SZUKAJ.TEKST(D2;A2:A10))*PRAWY(A2:A10;2));SZUKAJ.TEKST(D2;A2:A10)*PRAWY(A2:A10;2);0))

Pamiętaj, żeby zatwierdzić ją Ctrl + Shift + Enter

P.S.

Wpis na podstawie Excel Magic Trick 1001

Jeśli chcesz dowiedzieć się więcej na temat Excela lub nie wiesz jak coś zrobić do mnie o tym w komentarzu pod spodem albo napisz do mnie bezpośrednio, ja w miarę możliwości odpowiem na Twoje pytanie.

Excel i Adam - kontakt

Bezpośredni odnośnik do filmu na youtube — Znajdź największą liczbę za fragmentem tekstu — sztuczki #25