Excel - kurs online - oferta dla każdego

Nie znasz dobrze obsługi Excela? A może nie znasz jej wcale? Doskonale wiem, że w dzisiejszych czasach i realiach, znajomość tego programu jest nie tylko niezbędna, ale przede wszystkim korzystna dla Ciebie samego. Moje szkolenie z Excela online pokaże Ci, że arkusz kalkulacyjny nie jest wcale Twoim wrogiem, a sprzymierzeńcem w porządkowaniu i analizie danych - nie tylko liczbowych. Stworzyłem kurs Excel online na każdym poziomie, zarówno dla osób początkujących, średniozaawansowanych, jak i zaawansowanych. Znajdziesz u mnie także szkolenie z Excela online dedykowane specjalnie przedsiębiorcom. Każdy kurs zawiera starannie wyselekcjonowany zakres wiedzy i zagadnień, które odpowiadają na ściśle sprecyzowane potrzeby jego użytkowników.


Excel - kurs online. Dlaczego warto?

Zastanawiasz się, czy Excel i kurs online to dobre połączenie? Czy taka forma nauki pracy z arkuszem kalkulacyjnym może być efektywna? Pozwól, że rozwieję Twoje wątpliwości.

Od lat z powodzeniem zajmuję się dzieleniem swoją wiedzą zdalnie. Ta forma nauki, szczególnie w ostatnim czasie, mocno zyskała na popularności, a jej techniki znacząco się rozwinęły. Abyś mógł biegle posługiwać się programem Excel, każdy swój kurs zaprojektowałem z ogromną starannością i w oparciu o zasady metodyki nauczania na odległość.

Jednak szkolenie z Excela online, to przede wszystkim ogromna wygoda dla Ciebie, ponieważ nie musisz wychodzić z domu, możesz uczyć się wraz ze mną z dowolnego miejsca i w wybranym przez siebie czasie. Dodatkowo każdy mój kurs Excela online zawiera materiały dydaktyczne dostępne dla Ciebie już po zakończeniu szkolenia. Krótkie nagrania filmowe, prezentujące różnego rodzaju działania w arkuszu kalkulacyjnym, które w dowolnej chwili możesz zatrzymać, odtworzyć ponownie, by jeszcze raz przeanalizować i utrwalić wiedzę, to doskonały sposób, by opanować Excel. Kurs online to nie tylko wygoda, to także oszczędność Twojego i mojego czasu - zamiast dojeżdżać w umówione miejsce, możemy poświęcić więcej chwil na ćwiczenia i praktykę.

Jak policzyć ilość wielkiej litery U w komórkach — porada #285

Załóżmy, że potrzebujesz zliczyć komórki w których wystąpiła wielka litera "U", bo ona oznacza dla Ciebie coś istotnego, a mała litera "u", nie jest dla Ciebie istotna. Jak to zrobić.

Rozważmy dwie sytuacje. W pierwszej w komórce znajduje się tylko 1 litera. W drugiej w komórce jest więcej liter.

Porada 285 - Jak policzyć ilość wielkiej litery U w komórkach 01

W pierwszej sytuacji możemy skorzystać z funkcji PORÓWNAJ, która porównuje, czy dwa ciągi znaków są identyczne m.in. pod kątem wielkości liter. Zwykłe porównanie nie zapewniłoby rozróżnienia pomiędzy małymi, a wielkimi literami. Czyli środek naszej formuły będzie wyglądać tak:

=PORÓWNAJ(A2:A10;"U")

Porada 285 - Jak policzyć ilość wielkiej litery U w komórkach 02

Powyższa formuła zwraca wartości PRAWDA, gdy w komórce jest wielka litera "U" i FAŁSZ w przeciwnej sytuacji. Funkcja PORÓWNAJ zwraca odpowiedni ciąg tych wartości:

{FAŁSZ;FAŁSZ;PRAWDA;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;PRAWDA;FAŁSZ}

Musimy zsumować prawdy, ale, żeby uniknąć zatwierdzania formuły jako formuły tablicowej będziemy chcieli wspomóc się funkcją SUMA.ILOCZYNÓW, która radzi sobie z operacjami na tablicach, ale niestety ignoruje wartości logiczne PRAWDA i FAŁSZ. Dlatego musimy je zamieć odpowiednio na 1 i 0, wykonując na nich dowolną operację matematyczną. Najszybsza jest podwójna negacja, czyli dołożenie dwóch znaków minus przed funkcją PORÓWNAJ. W takiej sytuacji cała formuła będzie wyglądała tak:

Porada 285 - Jak policzyć ilość wielkiej litery U w komórkach 03

Teraz rozwiążmy drugą sytuację. Musimy sprawdzić, czy w poszczególnych tekstach z interesującego nas zakresu znajduje się wielka litera "U". Tym razem zaczniemy od funkcji ZNAJDŹ, która zwraca pozycję jednego ciągu tekstowego w innym tekście, a dodatkowo zwraca uwagę na wielkość liter.

=ZNAJDŹ("U";D2:D10)

Porada 285 - Jak policzyć ilość wielkiej litery U w komórkach 04

Jeśli funkcja ZNAJDŹ nie znajdzie szukanego tekstu to zwraca błąd argumentu, w przeciwnej sytuacji zwraca liczbę w omawianym przykładzie wynikiem będzie ciąg:

{#ARG!;2;#ARG!;1;#ARG!;#ARG!;2;#ARG!;#ARG!}

Na błędach trudno wykonywać sumowanie, dlatego musimy je przekształcić. W tej sytuacji najprościej skorzystać z funkcji CZY.LICZBA, wtedy uzyskamy wartości logiczne PRAWDA, gdy "U" udało się znaleźć, a FAŁSZ, gdy był błąd.

=CZY.LICZBA(ZNAJDŹ("U";D2:D10))

Porada 285 - Jak policzyć ilość wielkiej litery U w komórkach 05

Wychodzi ciąg — {FAŁSZ;PRAWDA;FAŁSZ;PRAWDA;FAŁSZ;FAŁSZ;PRAWDA;FAŁSZ;FAŁSZ}

Czyli znowu możemy skorzystać z funkcji SUMA.ILOCZYNÓW i uzyskujemy interesujący nas wynik:

=SUMA.ILOCZYNÓW(–CZY.LICZBA(ZNAJDŹ("U";D2:D10)))

Porada 285 - Jak policzyć ilość wielkiej litery U w komórkach 06

Pozdrawiam
Adam Kopeć
Miłośnik Excela

Jak wyszukiwać uwzględniając wielkość liter różne funkcje — widzowie #95

 

Tym razem do wyszukiwania z uwzględnieniem wielkości liter wykorzystamy inne funkcje niż WYSZUKAJ.PIONOWO. Rozpatrzymy dwa rozwiązania. Oba będą wykorzystały wynik funkcji PORÓWNAJ:

=PORÓWNAJ(E2;$A$2:$A$11)

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 01

Tak jak w poprzednich wpisach wynikiem będzie tablica wartości logicznych PRAWDA i FAŁSZ. PRAWDA, będzie w tych komórkach, gdzie ciągi tekstowe były identyczne w pozostałych będzie FAŁSZ.

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 02

Pierwsza formuła będzie jeszcze korzystać z funkcji PODAJ.POZYCJĘ oraz INDEKS. Za pomocą funkcji PODAJ.POZYCJĘ odnajdziesz wartość PRAWDA w wynikach funkcji PORÓWNAJ:

=PODAJ.POZYCJĘ(PRAWDA;PORÓWNAJ(F2;$A$2:$A$11);0)

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 03

A jak masz już pozycję prawdy, to wystarczy skorzystać z funkcji INDEKS, gdzie jako pierwszy argument wstawisz zakres kolumny, z której chcesz wyciągnąć wartość:

=INDEKS($C$2:$C$11;PODAJ.POZYCJĘ(PRAWDA;PORÓWNAJ(F2;$A$2:$A$11);0))

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 04

Pamiętaj tylko zatwierdzić formułę jako formułę tablicową – kombinacją klawiszy Ctrl + Shift + Enter.

Drugie rozwiązanie będzie wykorzystywało funkcję WYSZUKAJ. Tylko standardowo musisz odpowiednio przygotować dane, żeby z niej skorzystać. Tym razem wynik funkcji PORÓWNAJ posłuży jako dzielnik. Wystarczy, że wartość 1 podzielisz przez wynik funkcji PORÓWNAJ:

=1/PORÓWNAJ(F2;$A$2:$A$11)

Ponieważ w Excelu jeśli wykonasz dowolną operację matematyczną na wartościach logicznych PRAWDA lub FAŁSZ, to Excel zamieni je odpowiednio na liczby 1 i 0. To wynikiem takiego dzielenia, będzie tablica błędów dzielenia przez zero i liczby 1 (dla PRAWDA):

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 05

Teraz już możesz obudować naszą tablicę z wynikami funkcją WYSZUKAJ. Będziesz szukał liczby 2, ponieważ funkcja WYSZUKAJ zawsze działa na zasadzie dopasowania przybliżonego, dlatego jeśli karzesz jej szukać 2 w tablicy 1 i błędów dzielenia przez zero (#DZIEL/0!), to Excel znajdzie ostatnią liczbę 1. (Odwrotnie jak w pierwszej formule, która znajduje pierwsze wystąpienie szukanej wartości).

Potrzeba jeszcze tylko podać argument wektor_wynikowy, czyli analogicznie jak w funkcji INDEKS kolumnę, z której chcesz wyciągnąć wartość:

=WYSZUKAJ(2;1/PORÓWNAJ(F2;$A$2:$A$11);$C$2:$C$11)

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 06

To rozwiązanie fajne jest dlatego, gdyż nie wymaga zatwierdzania specjalna kombinacją klawiszy.

Odpowiednio wyniki dla dwóch zaprezentowanych formuł będą się różnić ze względu na ilość występujących tekstów i ich pozycje:

Widzowie 95 - Jak wyszukiwać z uwzględnieniem wielkości liter różne funkcje 07
Pozdrawiam
Adam Kopeć
Miłośnik Excela

Excel — Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ PIONOWO prostsze — Widzowie #94

Jeśli zależy Ci żeby wyszukiwać uwzględniając wielkość liter to musisz przygotować odpowiednią formułę. Dzięki komentarzowi Patryka Murowskiego pod wideo „Widzowie 93” poznałem prostszą formułę niż tą, którą znałem. Wykorzystuje m.in. funkcję WYSZUKAJ.PIONOWO. Będziemy działać na przykładowych danych:

Widzowie 94 - Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ.PIONOWO prostsze 01

Nasz obliczenia zaczniemy od funkcji PORÓWNAJ, która porównuje dwa ciągi tekstowe (uwzględniając wielkość liter) i w zależności od wyniku porównania zwraca wartość logiczną PRAWDA albo FAŁSZ. W naszym przykładzie potrzebujemy, jako jeden z argumentów funkcji PORÓWNAJ podać tekst, którego szukamy, a jako drugi odwołanie do kolumny, którą będziemy przeszukiwać:

=PORÓWNAJ(F2;$A$2:$A$11)

Widzowie 94 - Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ.PIONOWO prostsze 02

Przy takich danych funkcja PORÓWNAJ zwróci tablicę wartości logicznych PRAWDA i FAŁSZ. PRAWDA, będzie w tych komórkach, gdzie ciągi tekstowe były identyczne w pozostałych będzie FAŁSZ.

Widzowie 94 - Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ.PIONOWO prostsze 03

Teraz na podstawie wyników funkcji PORÓWNAJ stworzymy tablicę, po której będzie szukała funkcja WYSZUKAJ.PIONOWO. Wystarczy, że skorzystasz z funkcji JEŻELI, dla której tablica wartości logicznych PRAWDA i FAŁSZ będą argumentem test_logiczny. Gdy funkcja PORÓWNAJ będzie zwracała PRAWDĘ będziemy chcieli, żeby pokazywał się wiersz z danymi. To bardzo łatwo da się uzyskać, bo wystarczy podać zakres danych jako argument wartość_jeżeli_prawda. Natomiast argument wartość_jeżeli_fałsz możesz całkowicie pominąć, ponieważ domyślnie będzie zamiast niego zwracana wartość FAŁSZ.

=JEŻELI(PORÓWNAJ(F2;$A$2:$A$11);$A$2:$C$11)

Widzowie 94 - Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ.PIONOWO prostsze 04

Jeżeli podejrzysz wynik funkcji JEŻELI klawiszem F9, to zobaczysz, że zwracany jest wiersz danych tylko jeśli został znaleziony identyczny tekst. W innych sytuacjach są zwracane wiersze wartości FAŁSZ.

Widzowie 94 - Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ.PIONOWO prostsze 05

To pasuje idealnie do obliczeń, bo wystarczy, że wstawisz formułę do funkcji WYSZUKAJ.PIONOWO, która będzie szukała danego słowa, ponieważ tylko ona, lub wartość FAŁSZ jest w pierwszej kolumnie przeszukiwanej tablicy danych. Wystarczy jeszcze dopisać, że chcesz wyciągnąć wartość z 3 kolumny i dokonywać przeszukiwania na zasadzie dokładnej (czwarty argument = 0).

=WYSZUKAJ.PIONOWO(F2;JEŻELI(PORÓWNAJ(F2;$A$2:$A$11);$A$2:$C$11);3;0)

Widzowie 94 - Jak wyszukiwać z uwzględnieniem wielkości liter WYSZUKAJ.PIONOWO prostsze 06

Pamiętaj tylko zatwierdzić formułę jako formułę tablicową – kombinacją klawiszy Ctrl + Shift + Enter.
Pozdrawiam
Adam Kopeć
Miłośnik Excela

Excel — Jak sprawić by WYSZUKAJ PIONOWO zwracała uwagę na wielkość liter — widzowie #93

Funkcja WYSZUKAJ.PIONOWO nie zwraca uwagi, na wielkość znaków, więc jeśli Ci zależy, żeby Excel rozróżniał przy wyszukiwaniu wielkość liter, to musisz zbudować odpowiednią do tego formułę. Będziemy działać na przykładowych danych:

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 01

Nasz obliczenia zaczniemy od funkcji PORÓWNAJ, która porównuje dwa ciągi tekstowe (uwzględniając wielkość liter) i w zależności od wyniku porównania zwraca wartość logiczną PRAWDA albo FAŁSZ. W naszym przykładzie potrzebujemy, jako jeden z argumentów funkcji PORÓWNAJ podać tekst, którego szukamy, a jako drugi odwołanie do kolumny, którą będziemy przeszukiwać:

=PORÓWNAJ(E2;$A$2:$A$11)

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 02
Przy takich danych funkcja PORÓWNAJ zwróci tablicę wartości logicznych PRAWDA i FAŁSZ. PRAWDA, będzie w tych komórkach, gdzie ciągi tekstowe były identyczne w pozostałych będzie FAŁSZ.

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 03
Teraz potrzebujemy na tej podstawie powyższej tablicy stworzyć element, którego będziemy szukać. Relatywnym prostym rozwiązaniem będzie przemnożenie jej przez tablicę z numerami wierszy danych. Wystarczy, że wykorzystasz do tego funkcję WIERSZ z podanym zakresem kolumny, którą będziesz przeszukiwał. Jej wynik musimy przemnożyć przez tablicę zwracaną przez funkcję PORÓWNAJ:

=PORÓWNAJ(E2;$A$2:$A$11)*WIERSZ($A$2:$A$11)

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 04
Wynikiem iloczynu, będzie tablica z zerami oraz numerami wierszy, tylko tam, gdzie Excel znalazł identyczne ciągi tekstowe.

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 05
Nas będzie interesowała z tej tablicy maksymalna wartość, dlatego wystarczy nasze dotychczasowe obliczenia wstawić do funkcji MAX:

=MAX(PORÓWNAJ(E2;$A$2:$A$11)*WIERSZ($A$2:$A$11))

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 06
Uff. Udało się nam wyznaczyć wartość, której będziemy szukać za pomocą funkcji WYSZUKAJ.PIONOWO. Teraz potrzebujesz zbudować tablicę, którą funkcja będzie przeszukiwać. Do tego przyda Ci się funkcja WYBIERZ, która domyślnie zwraca wybrany argument na podstawie kolejności, czyli jeśli jako pierwszy argument wpiszesz 1 to funkcja WYBIERZ zwróci kolejny pierwszy argument, jeśli wpiszesz 2 to zwróci kolejny drugi argument itd. My jedna potrzebujemy, żeby funkcja WYBIERZ zwracała na raz dwa argument. Żeby uzyskać taki efekt musisz wpisać pierwszy argument jako tablicę danych: {1\2}. Dla takiego argumentu funkcja WYBIERZ zwróci zarówno pierwszy jak i drugi wybierany argument.
Na szczęście funkcja WYBIERZ nie ma problemu ze zwracaniem zakresów danych, więc nasz pierwszy argument to będą numery wierszy przeszukiwanej kolumny (WIERSZ($A$2:$A$11)), a drugi argument to będzie kolumna, z której chcemy wyciągnąć informację ($B$2:$B$11). Ponieważ funkcja WYSZUKAJ.PIONOWO zwraca z wartość z pojedynczej kolumny, to nawet jeśli Twoje dane źródłowe mają więcej kolumn to wystarczy, że podasz funkcji WYBIERZ tylko dwie kolumny, tą z numerami wierszy i kolumnę, z której chcesz pobrać wartość. Cała funkcja będzie wyglądała tak:

WYBIERZ({1\2};WIERSZ($A$2:$A$11);$B$2:$B$11)

Jeśli podejrzysz sobie jej wynik, to zobaczysz w jaki sposób Excel wizualizuje zapis jako tablica danych

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 07
Najtrudniejsze już za nami. Wystarczy, jeszcze podać dwa ostatnie argumenty funkcji WYSZUKAJ.PIONOWO – to wartość 2, bo szukamy wartości z drugiej kolumny i wartość 0, ponieważ chcemy wykonywać wyszukiwanie na zasadzie dopasowania dokładnego. Czyli cała formuła będzie miała taką strukturę:

=WYSZUKAJ.PIONOWO(MAX(PORÓWNAJ(E2;$A$2:$A$11)*WIERSZ($A$2:$A$11));WYBIERZ({1\2};WIERSZ($A$2:$A$11);$B$2:$B$11);2;0)

Widzowie 93 - Jak sprawić by WYSZUKAJ.PIONOWO zwracał uwagę na wielkość liter 08
Pamiętaj, że jest to formuła tablicowa, ponieważ podajemy funkcją Excela tablice, w argumentach, gdzie spodziewa się pojedynczej wartości, dlatego tą formułę musisz zatwierdzać kombinacją klawiszy Ctrl + Shift + Enter.

Pozdrawiam
Adam Kopeć
Miłośnik Excela

Jak sprawdzić czy tekst jest pisany tylko małymi lub tylko wielkimi literami — porada #106

Jak sprawdzić czy tekst jest pisany tylko małymi lub tylko wielkimi literami?


Jak sprawdzić czy tekst jest pisany tylko małymi lub tylko wielkimi literami — porada #106

Jak sprawdzić czy tekst jest pisany tylko małymi lub tylko wielkimi literami - porada #106

Jak sprawdzić czy tekst jest pisany tylko małymi, tylko wielkimi literami lub każde słowo zaczyna się od wielkiej litery?
To proste potrzebujemy funkcji PORÓWNAJ, która porównuje dwa ciągi tekstowe oraz funkcji, która zamienia nam tekst w zależności od potrze.

Czyli załóżmy, że chcesz znaleźć wszystkie firmy w danych i wiesz, że są one zapisywane KAPITALIKA. Wtedy potrzebujesz funkcji PORÓWNAJ i LITERY.WIELKIE:

=PORÓWNAJ(A4;LITERY.WIELKIE(A4))

Takie proste porównanie zwróci Ci wartość PRAWDA, gdy tekst będzie pisany tylko wielkimi literami (kapitalikami) w innych sytuacjach zwróci FAŁSZ.

P.S.

Jeśli chcesz dowiedzieć się więcej na temat Excela lub nie wiesz jak coś zrobić do mnie o tym w komentarzu pod spodem albo napisz do mnie bezpośrednio, ja w miarę możliwości odpowiem na Twoje pytanie.

Excel i Adam - kontakt

Bezpośredni odnośnik do filmu na youtube — Jak sprawdzić czy tekst jest pisany tylko małymi lub tylko wielkimi literami — porada #106