Jak znaleźć najmniejszą cyfrę z liczby (funkcja MIN lub AGREGUJ)?

Żeby znaleźć najmniejszą cyfrę z komórki trzeba się trochę natrudzić. Najpierw trzeba wyciągnąć po jednej wszystkie cyfry, a następnie znaleźć tą najmniejszą.


Najmniejsza cyfra z komórki za pomocą funkcji MIN lub AGREGUJ — sztuczki #20

Najpierw tworzymy formułę, która wyciągamy niejako odwołania do ilości wierszy

="1:"&DŁ(A2)

Formuła z funkcją DŁ - przygotowania do odwołań pośrednich

Formuła z funkcją DŁ — przygotowania do odwołań pośrednich

i ich odwołanie pośrednie

=ADR.POŚR("1:"&DŁ(A2))

Nie przejmuj się jeśli ta część zwraca niepoprawne wartości, bo nie o nie nam chodzi, tylko o to co uzyskamy, gdy wyciągniemy wartość z tej formuły za pomocą funkcji WIERSZ

=WIERSZ(ADR.POŚR("1:"&DŁ(A2)))

Przykładowy wynik tej formuły to {1;2;3;4;5;6} , czyli tablica z numerami pozycji poszczególnych cyfr. Ponieważ formuła zwraca tablicę, a nie da się wpisać poprawnie całej tablicy, do 1 komórki, dlatego Excel wyświetla tylko pierwszą wartość z ciągu tablicy, czyli w tych obliczeniach 1.

Przykładowy wynik przy sprawdzaniu formuły zapisanej powyżej i wyniki wpisywane w komórki

Przykładowy wynik przy sprawdzaniu formuły zapisanej powyżej i wyniki wpisywane w komórki

Następnie wyciągamy te cyfry:

=FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1)+0

Dodanie zera na końcu formuły służy zamianie wyniku funkcji FRAGMENT.TEKSTU z wartości traktowanych jako tekst ({"6";"4";"6";"5";"6";"4"}) na liczby ({6;4;6;5;6;4})

Teraz wystarczy znaleźć najmniejszą cyfrę:

=MIN(FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1)+0)

Niepoprawny wynik działania formuły tablicowej

Niepoprawny wynik działania formuły tablicowej

Zwróć uwagę na to, że funkcja MIN przyjmuje pojedyncze liczby, a podajemy jej całą tablicę cyfr. Jeśli odpowiednio jej nie zatwierdzisz zwróci niepoprawny wynik (pierwszą cyfrę liczby), ponieważ reszty nie bierze pod uwagę, bo nie dałeś jej znać, że ma być traktowana jako formuła tablicowa. Należy ją zatwierdzić naciskając Ctrl + Shift + Enter

Wtedy Excel w pasku formuły otoczy ją nawiasami klamrowymi

{=MIN(FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1)+0)}

Poprawny wynik formuły tablicowej po zaakcepetowaniu jej jako formuła tablicowa klawiszami Ctrl + Shift + Enter

Poprawny wynik formuły tablicowej po zaakcepetowaniu jej jako formuła tablicowa klawiszami Ctrl + Shift + Enter

żeby dać Ci znać, że będzie liczył tą formułę jako tablicowa (wpisanie samemu nawiasów klamrowych nic Ci nie da)

Zamiast funkcji MIN możesz wykorzystać funkcję AGREGUJ, która rodzi sobie z tablicami i nie trzeba mówić Excelowi, żeby traktował ją jako formułę tablicową.

=AGREGUJ(15;4;FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1)+0;1)

Wynik formuły z funkcją AGREGUJ nie musi być zatwierdzany jako formuła tablicowa

Wynik formuły z funkcją AGREGUJ nie musi być zatwierdzany jako formuła tablicowa

  • 1 argument (15) funkcji mówi, żeby funkcja liczyła na zasadzie funkcji MIN.K
  • 2 argument (4) funkcji mówi, żeby funkcja niczego nie ignorowała
  • 3 argument (FRAGMENT.TEKSTU(A2;WIERSZ(ADR.POŚR("1:"&DŁ(A2)));1)+0) to tablica do funkcji MIN.K
  • 4 argument (1) to parametr dla funkcji MIN.K, żeby znalazła najmniejszą cyfrę

P.S.

Wpis na podstawie Excel Magic Trick 994

Jeśli chcesz dowiedzieć się więcej na temat Excela lub nie wiesz jak coś zrobić do mnie o tym w komentarzu pod spodem albo napisz do mnie bezpośrednio, ja w miarę możliwości odpowiem na Twoje pytanie.

Excel i Adam - kontakt

Bezpośredni odnośnik do filmu na youtube — Najmniejsza cyfra z komórki za pomocą funkcji MIN lub AGREGUJ — sztuczki #20