0
0 Produkty w koszyku

No products in the cart.

Excel — Wyszukiwanie stawki godzinowej w zależności od liczby przepracowanych godzin — widzowie 123

W tym poście obliczymy kwotę, jaką należy wypłacić pracownikowi za ilość przepracowanych godzin. Trudność polega na tym, że stawka godzinowa wzrasta wraz z ilością przepracowanych godzin przez danego pracownika.

Zadanie to wykonamy na podstawie przykładowych danych z rys. nr 1.

Rys. nr 1 – przykładowe dane

Jak widać na rysunku powyżej, jeśli pracownik przepracował mniej niż 100 godzin, to stawkę bierzemy z kolumny F. Jeśli przepracowana została ilość godzin między 100 a 200 stawka godzinowa jest brana z kolumny G, a powyżej 200 godzin, mamy stawkę z kolumny H. Nasze zadanie polega na obliczeniu kwoty, jaka należy się pracownikowi za przepracowane godziny.

Zaczniemy od funkcji WYSZUKAJ.PIONOWO, za której pomocą odnajdziemy wiersz, w którym są dane dla wybranego pracownika. Pierwszy argument funkcji to szukana_wartość, czyli konkretny pracownik (komórka A2). Drugi argument funkcji to tabela_tablica, czyli dane w tabeli z rozpisanymi stawkami godzinowymi (zakres zablokowany bezwzględnie za pomocą klawisza F4, bo będziemy kopiować formułę w dół $E$2:$H$5). W tym zakresie nie zaznaczamy nagłówka, bo nie jest potrzebny. Trzeci argument funkcji to nr_indeksu_kolumny, czyli z której kolumny będziemy wybierać dane. Na tą chwilę wpiszemy tu na stałe wartość 2, czyli dane z drugiej kolumny dla ilości przepracowanych godzin do 100. W miejsce tego argumentu będziemy musieli napisać formułę, która będzie wybierać odpowiednią kolumnę w zależności od ilości przepracowanych godzin. Czwarty argument to przeszukiwany_zakres, czyli rodzaj dopasowania. Wpisujemy tutaj wartość 0 dla dopasowania dokładnego co widać na rys. nr 2.

Rys. nr 2 – wybór dopasowania w funkcji WYSZUKAJ.PIONOWO

Zapis formuły powinien wyglądać następująco:

=WYSZUKAJ.PIONOWO(A2;$E$2:$H$5;2;0)

Zatwierdzamy powyższą formułę i kopiujemy w dół. Otrzymamy stawki godzinowe dla poszczególnych pracowników przedstawione na rys. nr 3.

Rys. nr 3 – stawka godzinowa dla poszczególnych pracowników

Wyciągnęliśmy stawki godzinowe dla poszczególnych pracowników. Ale ta stawka jest wyciągnięta z kolumny F, czyli dla ilości przepracowanych godzin do 100. Stawka ta jest zależna od ilości przepracowanych godzin każdego pracownika podanych w kolumnie B. Aby uwzględnić te zmiany, musimy w miejsce wpisanego na stałe argumentu nr_indeksu_kolumny wstawić funkcję PODAJ.POZYCJĘ. Pierwszym argumentem funkcji jest szukana_wartość, czyli liczba przepracowanych godzin (B2). Drugi argument to przeszukiwana_tab, czyli nagłówki naszych danych z progami ilości godzin zablokowane bezwzględnie ($F$1:$H$1). Trzeci argument to typ_porównania, czyli mniejsze niż w naszym przykładzie – wpisujemy wartość 1 (rys. nr 4).

Rys. nr 4 – typy porównania w funkcji PODAJ.POZYCJĘ

Funkcja PODAJ.POZYCJĘ będzie szukała w której kolumnie znajduje się ilość przepracowanych godzin przez danego pracownika. Jeśli np. ilość godzin będzie wynosiła 200 to funkcja poda numer kolumny H. Musimy zwrócić uwagę, że wynik funkcji PODAJ.POZYCJĘ jest o 1 mniejsza niż ilość kolumn, których potrzebujemy w funkcji WYSZUKAJ.PIONOWO, bo zaznaczaliśmy o jedną kolumnę mniejszy zakres (tylko kolumny od F do H). Dlatego do tego argumentu musimy dodać wartość 1.

Zapis całej formuły powinien wyglądać następująco:

=WYSZUKAJ.PIONOWO(A2;$E$2:$H$5;PODAJ.POZYCJĘ(B2;$F$1:$H$1;1)+1;0)

Powyższą formułę zatwierdzamy i kopiujemy w dół. Otrzymamy dane przedstawione na rys. nr 5.

Rys. nr 5 – stawka godzinowa pracowników według ilości przepracowanych godzin

Otrzymaliśmy prawidłowe stawki godzinowe dla poszczególnych pracowników. Pozostaje nam pomnożyć stawkę godzinową przez ilość przepracowanych godzin. Zapis formuły powinien wyglądać następująco:

=B2*WYSZUKAJ.PIONOWO(A2;$E$2:$H$5;PODAJ.POZYCJĘ(B2;$F$1:$H$1;1)+1;0)

Powyższą formułę zatwierdzamy i kopiujemy w dół. Otrzymamy kwoty do wypłaty dla poszczególnych pracowników przedstawione na rys. nr 6.

Rys. nr 6 – obliczone kwoty do wypłaty

BD.ILE.REKORDÓW.A — Ile kontraktów zdobyły grupy menadżerów

W tym poście poznamy funkcję bazodanową i nauczymy się z niej korzystać — BD.ILE.REKORDÓW.A

Temat ten omówimy na podstawie przykładowych danych z rys. nr 1.

Rys. nr 1 – przykładowe dane

W tym zadaniu chcemy obliczyć, ile kontraktów podpisały poszczególne grupy pracowników. Wszystkie funkcje bazodanowe w Excelu zaczynają się od ciągu znaków BD. W tej funkcji będziemy liczyć niepuste komórki / zakresy. Formułę wpisujemy w komórkę F6. Pierwszym argumentem funkcji jest baza, czyli baza danych – cały zakres danych, z których będziemy chcieli wyciągnąć informacje. U nas jest to zakres $A$1:$C$25, zablokowany bezwzględnie. Zależy nam, żeby zakres danych się nie przesuwał, bo naszą formułę będziemy przeciągać w prawo. Drugi argument funkcji to pole, czyli kolumna wypełniona danymi z nazwami pracowników (kolumna 3). Trzeci argument funkcji to kryteria, czyli dane według których chcemy przeanalizować nasze dane (dane z kolumny F – F2:F5. Ten zakres zostawiamy względny, bo chcemy, aby przesuwał się odpowiednio przy przeciąganiu formuły. Jeśli naszym Menadżerem będą Jan, Mateusz lub Janina to funkcja BD.ILE.REKORDÓW.A będzie dodawać odpowiednie wartości, zliczać je. Zapis formuły powinien wyglądać następująco:

=BD.ILE.REKORDÓW.A($A$1:$C$25;3;F2:F5)

Powyższą formułę zatwierdzamy i kopiujemy w bok. Otrzymamy podliczone dane przedstawione na rys. nr 2.

Rys. nr 2 – podliczone rekordy dla poszczególnych grup pracowników

Jak widać na rysunku powyżej pierwsza grupa menadżerów podpisała 8 kontraktów, druga 3, a trzecia 13. Istotne jest, żeby zwracać uwagę na zakresy danych w formułach. Tutaj mamy łatwą sytuację, bo w każdej grupie mamy 3 pracowników (ta sama ilość). Gdybyśmy usunęli jednego pracownika z drugiej grupy otrzymamy błędny wynik, co widać na rys. nr 3.

Rys. nr 3 – błędny wynik po usunięciu jednego pracownika

Wartość sprzedaży podskoczyła do 24. Dzieje się tak dlatego, że tutaj budowane są kryteria na zasadzie lub. Interesuje nas sprzedawca Suzan lub Róża lub puste pole, czyli dowolna wartość w komórce. Podsumowując w miejsce pustego pola zostały podliczone wartości sprzedaży dla każdego innego sprzedawcy niż Suzan i Róża. Zostały podliczone dokładnie wszystkie możliwe wiersze z nazwami menadżerów (niepuste wiersze). Gdyby dowolny wiersz z nazwą pracownika był pusty nie zostałby zliczony, co widać na rys. nr 4.

Rys. nr 4 – nie zliczony pusty wiersz z kolumny C

Podsumowując funkcja BD.ILE.REKORDÓW.A zlicza wszystkie wystąpienia menadżerów według podanych kryteriów. Kryteria rozpatrywane są na zasadzie lub.

Power Query 64 — Suma ze zmiennej ilości kolumn rozwiązanie w Excelu

W tym poście omówimy sumę ze zmieniającej się ilości kolumn w danych. Będzie to rozwiązanie problemu z Power Query w Excelu.

Zadanie to wykonamy na podstawie przykładowych danych z rys. nr 1.

Rys. nr 1 – przykładowe dane

Mamy tutaj wynik zapytania Power Query, który tworzy podsumowanie z danych z pierwszej tabeli. Mamy na razie przedstawione tylko 3 miesiące, ale pod spodem dojdą kolejne dane z dodatkowymi miesiącami (rys. nr 2).

Rys. nr 2 – dodatkowe dane

W podsumowaniu z Power Query chcemy mieć kolumnę "Suma". Można dodawać kolumny do zapytania Power Query, tylko trzeba mieć na uwadze, że ilość kolumn w Power Query może się zmienić. Tutaj standardowo chcielibyśmy otrzymać sumę. Użyjemy skrótu klawiszowego Alt + =. Excel wstawi nam automatycznie funkcję SUMA, jak widać na rys. nr 3.

Rys. nr 3 – funkcja SUMA

Możemy sobie uprościć zapis tej funkcji i wstawić w niej ręcznie odpowiedni zakres zamiast nazw tekstowych. Zapis będzie wtedy wyglądał następująco:

=SUMA(I2:K2)

Otrzymamy zsumowane dane w kolumnie L przedstawione na rys. nr 4.

Rys. nr 4 – zsumowane dane

Nasza suma przedstawia wynik z aktualnej sytuacji. Problem polega na tym, że jeśli wstawimy w dane kolejną kolumnę (Kwiecień) i dopiszemy jakieś wartości, to nie zostaną one uwzględnione w kolumnie Suma (rys. nr 5). Nasza Suma się nie rozszerzy, jej zakres się nie zmieni.

Rys. nr 5 – nieuwzględnione dane z Kwietnia w kolumnie Suma

Wróćmy do stanu sprzed dodania dodatkowej kolumny za pomocą skrótu klawiszowego Ctrl+Z. Jeśli natomiast wstawimy kolumnę między np. Lutym a Marcem i wpiszemy jakieś wartości liczbowe, to zostaną one uwzględnione w sumie (rys. nr 6). Zakres Sumy się rozszerzy.

Rys. nr 6 – uwzględnione dane w sumie

Problem pojawia się, gdy nasze dane zostaną rozszerzone o kolumnę obok zakresu uwzględnionego w formule funkcji SUMA. W takiej sytuacji funkcja się nie rozszerza automatycznie, nie dopasowuje do nowego zakresu. Najprostszym rozwiązaniem jest użycie funkcji Excela. Jest możliwe rozwiązanie tego problemu w Power Query, ale jest bardziej skomplikowane i wymaga użycia kilku funkcji. Rozwiązanie to pokażemy w kolejnym poście.

Naszym zadaniem jest dynamiczne ustalenie zakresu funkcji SUMA. Możemy użyć funkcji PRZESUNIĘCIE. Pierwszym argumentem funkcji jest odwołanie, czyli komórki z zakresu I2:L2 (obejmujemy zakresem kolumnę Suma). Musimy ograniczyć to przesunięcie do ilości kolumn minus jedna kolumna. Czyli nie przesuwamy o konkretną ilość wierszy (argument wiersze), czy kolumn (argument kolumny), ale musimy zmienić argument szerokość (czwarty argument). Trzeci argument, czyli szerokość wstawiamy wartość 1. Musimy policzyć liczbę kolumn. Możemy to zrobić za pomocą funkcji LICZBA.KOLUMN. Argumentem funkcji jest tablica, czyli zakres obejmujący nasze 4 kolumny minus jedna kolumna (I2:L2‑1). Zapis formuły powinien wyglądać następująco:

=SUMA(PRZESUNIĘCIE(I2:L2;0;0;1;LICZBA.KOLUMN(I2:L2)-1))

Powyższą formułę zatwierdzamy. Sprawdzimy teraz, czy działa prawidłowo. Zaznaczamy kolumnę L i za pomocą skrótu klawiszowego Ctrl + Shift + Add wstawiamy nową kolumnę przed tą zaznaczoną. Następnie ręcznie wpisujemy dowolną wartość w tej kolumnie. Wynik w kolumnie Suma automatycznie ulegnie zmianie co widać na rys. nr 7.

Rys. nr 7 – uwzględnione dane z nowej kolumny w Sumie

Teraz musimy usunąć dodaną kolumnę ręcznie za pomocą skrótu klawiszowego Ctrl+Shift+Subtract. Teraz sprawdzimy, czy jeśli dodamy dużą ilość danych, zakres kolumn i sumy rozszerzy i przeliczy się prawidłowo. Dodatkowe dane z rysunku nr 2 zaznaczamy i przesuwamy w górę, czyli doklejamy do naszych danych źródłowych. Następnie odświeżamy dane z zapytania, czyli klikamy prawym przyciskiem myszy w dowolnym punkcie tabeli i z podręcznego menu wybieramy polecenie Odśwież (rys. nr 8).

Rys. nr 8 – polecenie Odśwież w podręcznym menu

Otrzymamy odświeżone (zaktualizowane) dane przedstawione na rys. nr 9.

Rys. nr 9 – odświeżone dane

Jak widać na rysunku powyżej nasze dane się przeliczyły, zakres Sumy odpowiednio się rozszerzył i otrzymaliśmy prawidłowe wyniki.

Excel — Podsumowanie sprzedaży po dniu tygodnia na podstawie daty — porada 423

W tym poście omówimy podsumowanie sprzedaży według dni tygodnia.

Zadanie to wykonamy na podstawie przykładowych danych z rys. nr 1.

Rys. nr 1 – przykładowe dane

Mamy niezbędne dla nas dane, czyli datę i wartość sprzedaży. Na tej podstawie chcemy uzyskać podsumowanie, ile transakcji odbyło się w każdym dniu tygodnia i jaka to była wartość sprzedaży. Na konkretny dzień tygodnia możemy patrzeć po jego nazwie lub po numerze (rys. nr 2).

Rys. nr 2 – podsumowanie, jakie chcemy uzyskać

Możemy tutaj użyć funkcji DZIEŃ.TYG, która na podstawie daty podaje dzień tygodnia. Pierwszym argumentem funkcji jest liczba_kolejna, czyli data, z której chcemy wyciągnąć dzień tygodnia. Drugi argument funkcji to [zwracany_typ], gdzie musimy zwrócić uwagę, jak są numerowane dni tygodnia. Standardowa numeracja jest tutaj określana liczbą 2, co widać na rys. nr 3.

Rys. nr 3 – typy numeracji dni tygodnia dla funkcji DZIEŃ.TYG

Zapis funkcji powinien wyglądać następująco:

=DZIEŃ.TYG(A2;2)

Powyższą formułę zatwierdzamy i kopiujemy na komórki poniżej. Otrzymamy numery dni tygodnia dla poszczególnych dat przedstawione na rys. nr 4.

Rys. nr 4 – numery dni tygodnia dla poszczególnych dat

Jeśli będziemy mieli numerację dni tygodnia, to możemy wykorzystać dane z kolumny G. Możemy również wykorzystać funkcję TEKST i odpowiednio sformatować datę. Pierwszym argumentem funkcji TEKST jest wartość, czyli nasza data. Drugi argument to format_tekst, czyli oznaczenie formatu "dddd", które powoduje wyświetlanie pełnej nazwy tekstowej dnia tygodnia. Zapis formuły powinien wyglądać następująco:

=TEKST(A2;"dddd")

Powyższą formułę zatwierdzamy i kopiujemy na komórki poniżej. Podsumowując, jeśli datę z kolumny A, sformatujemy jako "dddd", to otrzymamy pełną nazwę dnia tygodnia (rys. nr 5).

Rys. nr 5 – pełna nazwa dnia tygodnia dzięki funkcji TEKST

Jak widać w danych powyżej wartości z kolumn C i D ze sobą korespondują, tzn. jeśli mamy np. wartość 3 w kolumnie C, to w kolumnie D mamy dzień o nazwie Środa itd.

Jeśli możemy sobie pozwolić na zbudowanie w danych dodatkowych kolumn (pomocniczych), to możemy użyć funkcji SUMA.WARUNKÓW lub  SUMA.JEŻELI. My jednak założymy, że nie mamy możliwości zbudowania takich kolumn pomocniczych, dlatego takie obliczenia musimy wykonać wewnątrz jednej formuły. A funkcja SUMA.WARUNKÓW nie pozwala na obliczenia w jej wnętrzu.

W pierwszej kolejności musimy sprawdzić dzień tygodnia, ale dla całej kolumny A. Użyjemy do tego funkcji DZIEŃ.TYG. Zaznaczamy komórkę A2 i za pomocą skrótu klawiszowego Ctrl+Shift+Strzałka w dół zaznaczamy całą kolumnę. Podany zakres blokujemy bezwzględnie za pomocą klawisza F4. W argumencie zwracany_typ wybieramy wartość 2 (dla numeracji poniedziałek — 1, niedziela – 7). Zapis formuły powinien wyglądać następująco:

=DZIEŃ.TYG($A$2:$A$1998;2)

Ze względu na to, że pracujemy na Excelu tablicowym, po zatwierdzeniu formuły, wyniki rozleją się na odpowiednią ilość komórek (rys. nr 6).

Rys. nr 6 – rozlana formuła funkcji DZIEŃ.TYG

Interesuje nas, kiedy wartości z kolumny H są równe wartością z kolumny G. Zapis formuły powinien wyglądać następująco:

=DZIEŃ.TYG($A$2:$A$1998;2)=G2

Po zatwierdzeniu formuły otrzymamy wartości logiczne PRAWDA i FAŁSZ przedstawione na rys. nr 7.

Rys. nr 7 – wartości logiczne PRAWDAFAŁSZ

Nie ma znaczenia, jeśli nie posiadasz Excela tablicowego, to tylko ułatwia pokazywania rozlewających się formuł. Teraz musimy zamienić nasze wartości logiczne na wartości 1 i 0. Możemy to zrobić za pomocą podwójnej negacji, czyli wstawiamy dwa znaki minus przed funkcję. Zapis powinien wyglądać następująco:

=–(DZIEŃ.TYG($A$2:$A$1998;2)=G2)

Po zatwierdzeniu formuły otrzymamy wartości 0 i 1. Wartość logiczna PRAWDA zostanie zamieniona na 1, a FAŁSZ na 0 (rys. nr 8).

Rys. nr 8 – wartości logiczne zamieniona na 1 i 0

Teraz możemy łatwo zsumować nasze wyniki. Żebyśmy nie musieli tej formuły zatwierdzać w klasycznym Excelu kombinacją klawiszy Ctrl+Shift+Enter, korzystamy z funkcji SUMA.ILOCZYNÓW. Argumentem funkcji jest tablica1, czyli tablica uzyskana z poprzedniej formuły. Zapis powinien wyglądać następująco:

=SUMA.ILOCZYNÓW(–(DZIEŃ.TYG($A$2:$A$1998;2)=G2))

Po zatwierdzeniu formuły skrótem klawiszowym Ctrl+Enter otrzymamy ilość wszystkich transakcji przypadających na poniedziałek. Po skopiowaniu formuły w dół, otrzymamy dane dla pozostałych dni tygodnia (rys. nr 9).

Rys. nr 9 – ilość wszystkich transakcji dla poszczególnych dni tygodnia

Żeby obliczyć wartość sprzedaży postępujemy bardzo podobnie. Możemy skopiować poprzednią formułę. Zamiast podwójnej negacji (dwa minusy) zrobimy operację mnożenia przez kolumnę Sprzedaż, czyli zakres $B$2:$B$1998. Na chwilę usuniemy też funkcję SUMA.ILOCZYNÓW. Zapis formuły powinien wyglądać następująco:

=DZIEŃ.TYG($A$2:$A$1998;2)=G2)*$B$2:$B$1998

Po zatwierdzeniu formuły otrzymamy rozlane wartości sprzedaży z podaną wartością dla poniedziałku przedstawione na rys. nr 10.

Rys. nr 10 – rozlane wartości sprzedaży dla każdego poniedziałku

Aby otrzymać wyniki dla wszystkich dni tygodnia musimy otoczyć poprzednią formułę funkcją SUMA.ILOCZYNÓW. Zapis formuły powinien wyglądać następująco:

=SUMA.ILOCZYNÓW((DZIEŃ.TYG($A$2:$A$1998;2)=G2)*$B$2:$B$1998)

Po zatwierdzeniu formuły skrótem klawiszowym Ctrl+Enter i skopiowaniu w dół otrzymamy wartości sprzedaży dla poszczególnych dni tygodnia przedstawione na rys. nr 11.

Rys. nr 11 — wartości sprzedaży dla poszczególnych dni tygodnia

Excel — Tłumacz funkcji w Excelu — porada 422

W tym poście poznamy działanie tłumacza funkcji w Excelu.

Chodzi o takie dodatkowe okienko, które najczęściej znajduje się z boku ekranu po prawej stronie (rys. nr 1).

Rys. nr 1 – Tłumacz funkcji

Od kiedy w Excelu na karcie Wstawianie pojawiła się grupa poleceń Dodatki (rys. nr 2), czyli niejako sklep, możemy sobie pobierać dostępne dodatki. Jednym z takich dodatków jest właśnie Tłumacz funkcji.

Rys. nr 2 – grupa poleceń Dodatki

Wybieramy polecenie Pobierz dodatki z karty Wstawianie (jak na rys. nr 2). Otworzy nam się okno Dodatki pakietu Office, gdzie w polu Wyszukaj wpisujemy nazwę dodatku, jakiego szukamy (rys. nr 3). Istotne jest, że sklep Office działa w języku angielskim, więc nazwę dodatku musimy podać w tym właśnie języku.

Rys. nr 3 – okno Dodatków pakietu Office

Po znalezieniu dodatku, jaki nas interesuje, klikamy przycisk Dodaj. Pojawi nam się komunikat Excela dotyczący postanowień licencyjnych i ochrony prywatności, który musimy zatwierdzić przyciskiem Kontynuuj (rys. nr 4).

Rys. nr 4 – komunikat Excela o licencji i ochronie prywatności

Dodatek zostanie zainstalowany i zaraz po instalacji pojawi się na końcu karty Narzędzia główne, co widać na rys. nr 5 (Translator).

Rys. nr 5 – dodatek Translator na karcie Narzędzia główne

Zadaniem tego dodatku jest tłumaczenie nazw funkcji Excela. W oknie Functions Translator w zakładce Dictionary możemy zacząć pisać nazwę funkcji np. ZAOKR.W.GÓRĘ, pod spodem pojawi nam się angielska nazwa tej funkcji, czyli CEILING (rys. nr 6).

Rys. nr 6 – działanie dodatku Functions Translator

Analogicznie dodatek zadziała, jeśli wpiszemy angielską nazwę funkcji np. SUMPRODUCT, mianowicie zostanie ona przetłumaczona na polską funkcję SUMA.ILOCZYNÓW. Oczywiście nie jesteśmy ograniczeni do tych dwóch języków, możemy kliknąć ikonkę koła zębatego w prawym dolnym rogu okna Functions Translator. Pojawią się nam ustawienia tłumacza, gdzie w grupie Usage languages możemy ustawić dowolny język, jaki jest obsługiwany przez Excela (rys. nr 7).

Rys. nr 7 – ustawienia preferowanych języków

W tym dodatku mamy również zakładkę Reference, czyli bibliotekę funkcji Excela. Możemy sobie wybrać kategorię funkcji, której szukamy (rys. nr 8).

Rys. nr 8 – kategorie funkcji Excela

Jeśli wybierzemy sobie np. kategorię Logical, to wyświetli się nam lista wszystkich dostępnych funkcji logicznych z nazwami w obu wybranych językach, czyli w naszym przypadku po polsku i angielsku (rys. nr 9).

Rys. nr 9 – lista funkcji Excela z kategorii Logical

Moim zdaniem najciekawszą funkcjonalnością tego tłumacza jest zakładka Translator, w którym możemy tłumaczyć całe formuły. Możemy skopiować sobie dowolną formułę np. =ZAOKR(B2,0), następnie wklejamy ją do pierwszego okienka. Klikamy ikonkę ze Strzalką w dół, aby Excel przetłumaczył nam formułę. W okienku poniżej pojawi nam się przetłumaczona formuła =ROUND(B2,0) (rys. nr 10). Istotne tutaj jest, aby zawracać uwagę, jakie znaki rozdzielają część całkowitą od dziesiętnej czy poszczególne argumenty.

Rys. nr 10 – tłumaczenie formuł w zakładce Translator

Na dole okna jest dodatkowa opcja – Instantly translate  selected sell (English > Polish). Zaznaczenie tego checkbopxa powinno sprawić, że po kliknięciu dowolnej komórki z formułą, otrzymamy w oknie Functions Translator przetłumaczoną jej wersję (rys. nr 11).

Rys. nr 11 – automatyczne tłumaczenie funkcji w klikanych komórkach

Zauważyłem jednak, że przy bardzo skomplikowanych i długich formułach mogą pojawić się błędy, czasem formuły przekraczają możliwości tłumacza. Funkcjonalność ta przydaje się, jeśli potrzebujesz przetłumaczyć funkcje w Excelu w dowolnych językach.