Elementy z listy A które zawierają elementy listy B filtry zaawansowane – widzowie #118

Załóżmy, że masz trudne zadanie wyciągnięcia wszystkich elementów listy A, które zawierają elementy z listy B.

Widzowie 118 - Elementy z listy A, które zawierają elementy z listy B (filtry zaawansowane) 01

Tym razem, w porównania do pytania widzów 117, chcemy to zadanie zrobić za pomocą filtrów zaawansowanych, a nie formuł. Jest to prostszy sposób, ale nie daje możliwości dynamicznej zmiany wyniku, gdy zmienimy sprawdzane dane (przy zmianie danych musimy ponownie uruchomić filtry zaawansowane, na szczęście będą one pamiętać większość opcji).
Zacznijmy od tego, że filtry zaawansowane pozwalają na wyciąganie wartości na zasadzie lub jeśli tylko kryteria zapisujemy w kolejnych wiersza. Nasze kryteria to z założenia, czy dana fraza występuje na liście A. Żeby zapisać taki warunek w filtrach zaawansowanych musimy odrobinę zmodyfikować listę B, a mianowicie potrzebujemy dodać gwiazdkę (symbol wieloznaczny w Excelu, który zastępuje dowolny ciąg znaków, również pusty) na początku każdego elementu listy. Wystarczy, że zrobimy proste łączenie.

=”*”&C2

Widzowie 118 - Elementy z listy A, które zawierają elementy z listy B (filtry zaawansowane) 02

Ważne jest też, żeby nasza nowo utworzona lista miała taki sam nagłówek jak lista A (wymagane do poprawnego działania filtrów zaawansowanych). Teraz możemy już uruchomić filtry zaawansowane z karty dane (gdy mamy zaznaczona pojedynczą komórkę na liście A).

W oknie, które się pojawi musimy odpowiednio wypełnić pola. Zakres listy – lista A, Zakres kryteriów – zmodyfikowana lista B, kopiujemy do na początek pustego pola.

Widzowie 118 - Elementy z listy A, które zawierają elementy z listy B (filtry zaawansowane) 03

Zatwierdzamy wpisane parametry i uzyskujemy wynik we wskazanym miejscu. Jeśli dane ulegną zmianie, musimy ponownie uruchomić filtry zaawansowane i pamiętać zaznaczyć opcję, że chcemy dane kopiować, żeby Excel nie przefiltrował nam listy A (wynik też dostanie nagłówek listy A, ale najważniejsze są dla nas wyszukane wartości).

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Jak znaleźć elementy z listy A, które zawierają elementy z listy B formuła – widzowie #117

Załóżmy, że masz trudne zadanie wyciągnięcia wszystkich elementów listy A, które zawierają elementy z listy B.

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 01

Czyli w prostym przykładzie na liście B, mamy elementy „ewa” i „stefan”. Dlatego z listy A musimy wyciągnąć elementy „ewa” oraz „ewa mokra” bo zawierają element z listy B („ewa”). Musimy wyciągnąć również elementy „stefan” i „nowak stefan”, bo zawierają element z listy B („stefan”). Pozostałych elementów listy A nie wyciągamy, bo nie mają wspólnych części z listą B.
Ręcznie proces jest zrozumiały, ale czasochłonny przy dłuższych listach, jak więc to zrobić w Excelu, żeby wyciągnąć interesujące nas elementy za pomocą formuł w Excelu? (w filmie widzowie 118 – możesz zobaczyć jak zrobić to za pomocą filtrów zaawansowanych, co jest prostszą czynnością, ale nie może być dynamiczne jak formuły).

Będziemy potrzebowali kolumny pomocniczej. Zaczniemy od funkcji ZNAJDŹ, która pozwoli nam zidentyfikować, czy któryś z elementów listy B znajduje się w danym elemencie listy A.

=ZNAJDŹ($D$2:$D$3;A2)

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 02

Funkcja ZNAJDŹ zwraca numer znaku od którego szukany tekst (element listy B) znajduje się w konkretnym elemencie listy A (odwołanie do komórki A2). Jeśli go nie znajdzie zwraca błąd argumentu.

Ponieważ szukamy elementów z listy (tablicy) funkcja ZNAJDŹ zwraca nam również listę (tablicę), jeśli podejrzymy jej wynik klawiszem F9 w trybie edycji komórki to zobaczymy 2 wyniki – {1\#ARG!} (tyle mamy elementów listy B). Oznacza to, że w pierwszym elemencie listy A został odnaleziony pierwszy element listy B (na 1 znaku), a drugi element listy B już nie został odnaleziony.

Nam zależy na tym, żeby wiedzieć, czy chociaż jeden element został odnaleziony, czyli musimy policzyć wszystkie liczby. Możemy to zrobić korzystając z funkcji CZY.LICZBA , która zwróci nam wartość PRAWDA czy podana jej wartość jest liczbą oraz wartość FAŁSZ, jeśli podana jej wartość nie jest liczba (np.: jest błędem).

=CZY.LICZBA(ZNAJDŹ($D$2:$D$3;A2))

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 03

Czyli dla pierwszego elementu będziemy mieli wynik {PRAWDA\FAŁSZ}. Wartości PRAWDA i FAŁSZ może być ciężko zliczyć poza tym chcemy uniknąć zatwierdzania naszej formuły jako formuły tablicowej, więc zamieniamy wartości logiczne na 0 i 1 za pomocą podwójnej negacji (dwóch znaków minus), a następnie wstawiamy jest do funkcji SUMA.ILOCZYNÓW, żeby zsumować całą listę naszych wyników.

=SUMA.ILOCZYNÓW(–CZY.LICZBA(ZNAJDŹ($D$2:$D$3;A2)))

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 04

Teraz mamy 0 gdy, żaden element z listy B nie został odnaleziony w elemencie listy A, a wartości większe od 0 (u nas tylko 1), gdy chociaż jeden element z listy B został znaleziony w konkretnym elemencie listy A. Ale jeszcze nie skończyliśmy obliczeń, bo zwracane wartości (rys. 4) nie pomogą nam łatwo odnaleźć konkretnych elementów listy A, dlatego chcemy je zamienić na numer wiersza w liście A. Możemy to zrobić za pomocą funkcji JEŻELI i funkcji WIERSZ. Funkcja JEŻELI posłuży nam do tego, żeby dodatkowo rozróżnić interesujące nas elementy i te niechciane, bo jeśli wynik wcześniejszych obliczeń będzie większy od zera to zwróci numer wiersza (WIERSZ() – WIERSZ($A$1)), a jeśli będzie równy zero to zwróci FAŁSZ (trzeci argument funkcji JEŻELI pominięty.

=JEŻELI(SUMA.ILOCZYNÓW(–CZY.LICZBA(ZNAJDŹ($D$2:$D$3;A2)));WIERSZ()-WIERSZ($A$1))

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 05

Jeśli funkcji WIERSZ nie podamy żadnej wartości, to zwróci numer wiersza arkusza, w którym aktualnie się znajduje, a ponieważ nam zależy na numerze wiersza listy A, a nie arkusza, to musimy jeszcze odjąć numer wiersza nagłówka (WIERSZ($A$1)).
Jak mamy już ponumerowane interesujące nas elementy, to wyciągnięcie ich jest relatywnie proste. Przede wszystkim będziemy potrzebować funkcji INDEKS, żeby wiedzieć skąd wyciągamy elementy oraz dodatkowo funkcji MIN.K lub MAX.K, żeby wyciągać poszczególne elementy po kolei. Jedynym odrobinę trudniejszym elementem jest wyznaczenie kolejnych ‘k’. Robi się to najczęściej za pomocą funkcji ILE.WIERSZY z dynamicznie rozrastającym się zakresem – pierwsza część zakresu jest zablokowana bezwzględnie, a druga względnie ($F$2:F2). Cała formuła przyjmie postać:

=INDEKS($A$2:$A$7;MIN.K($B$2:$B$7;ILE.WIERSZY($F$2:F2)))

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 06

Pojawiać się tutaj będą błędy (#LICZBA!), gdy przeciągniemy formułę niżej niż mamy interesujących nas elementów. Najprościej poradzić sobie z tym funkcją JEŻELI.BŁĄD, ale jeśli nie chcemy, żeby Excel za każdym razem obliczał formułę wewnątrz funkcji JEŻELI.BŁĄD, to możemy policzyć wszystkie wartości większe od zera w kolumnie pomocniczej (=LICZ.JEŻELI($B$2:$B$7;”>0″)), a następnie sprawdzać, czy nie zeszliśmy już dalej niż jest interesujących nas elementów:

=JEŻELI(ILE.WIERSZY($F$2:F2)>$H$2;””;INDEKS($A$2:$A$7;MIN.K($B$2:$B$7;ILE.WIERSZY($F$2:F2))))

Widzowie 117 - Jak znaleźć wartości z listy A, które zawierają elementy listy B 07

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Excel – Slopegraph – porada #293

Czasami potrzebujesz porównać ze sobą wartości „przed” i „po” dla wielu np.: produktów. Jednym ze sposobów na to jest skorzystanie z tzw. slopegraphu, czyli wykresu, którego pomysłodawcą Edward Tufte.

Porada 293 - Wykres slope graph 01

Ten wykres opiera się na wykresie liniowym, ale ważnym jego elementem są etykiety danych na końcach linii. Standardowe podejście tworzenia tych etykiet uwzględnia dużo ręcznej pracy, dlatego na podstawie swoje wiedzy o wykresach spróbowałem swoich sił i chce zaproponować inne podejście. Do tego potrzebujemy stworzyć kolumny pomocnicze, które będą zawierały tylko wartość 1 lub 2 oraz jeszcze jedną kolumnę pomocniczą, która będzie przechowywać połączone wartości, które chcemy wyświetlać w etykietach danych.

Porada 293 - Wykres slope graph 02

=KWOTA(C3;0)&” „&A3

Korzystamy tu z funkcji KWOTA, żeby liczbę przedstawić jako walutę w złotówkach z dokładnością do zera miejsc po przecinku.
Slopegraph opiera się o wykres liniowy, więc od niego zaczniemy – zaznaczymy zakres komórek od A2 do C11 i z karty Wstawianie wstawimy wykres liniowy.

Porada 293 - Wykres slope graph 03

Tylko nie jest to wykres liniowy jakiego potrzebujemy, bo są na nim tylko 2 serie, a my potrzebujemy serii dla każdego produktu. Dlatego musimy kliknąć w polecenie Przełącz wiersz/kolumnę z karty Projektowanie narzędzi wykresów, żeby zamienić miejscami serie i kategorie.

Porada 293 - Wykres slope graph 04

Uzyskujemy już wykres, który bardzo przypomina slopegraph, ale musimy go jeszcze oczyścić z wszystkich niepotrzebnych rzeczy. Nie są nam potrzebne:
• Legenda
• Osie siatki
• Etykiety osi y

Dlatego wszystkie je możemy usunąć zaznaczając je i naciskając klawisz Delete.

Porada 293 - Wykres slope graph 05

Warto tu wspomnieć o pewnej sztuczce, żeby wartości 2014 i 2017 zostały użyte jako etykiety na osi x, a nie zostały dołożone do serii danych – przed nimi wstawiamy pojedynczy cudzysłów ‚ dzięki czemu Excel traktuje te liczby jako tekst i nie dodaje je do serii danych.

Slopegraph powinien być wyższy dlatego klikamy na obszar kreślenia i odpowiednio go poszerzamy.

Porada 293 - Wykres slope graph 06

Teraz potrzebujemy dodać jeszcze jedną serię, której zaraz będziemy musieli zmienić typ wykresu, więc nie ma dużego znaczenia jakie będzie miała ona wartości, żeby tylko nie została podpięta pod którąś z istniejących serii. Jednym z prostszych sposobów na to jest skopiowanie komórki A2 (Ctrl + C) z tekstem, zaznaczenie wykresu i wklejenie skopiowanego obszaru (Ctrl + V). Nie powinno być widać żadnych widocznych zmian na wykresie, ale jeśli skorzystasz z polecenia Zaznacz dane z karty Projektowanie to powinieneś zobaczyć, że dodała się nowa seria (Seria 10) do serii wykresu.

Porada 293 - Wykres slope graph 07

Ta seria posłuży nam do dodawania etykiet danych, ale musimy jej zmienić typ wykresu na punktowy. Czyli najpierw musimy ją zaznaczyć. Najprościej to zrobić korzystając z listy rozwijanej na karcie Formatowanie narzędzi wykresów.

Porada 293 - Wykres slope graph 08

Teraz możemy skorzystać z polecenie Zmień typ wykresu z karty Projektowanie narzędzi wykresów.

Porada 293 - Wykres slope graph 09

Dużo prościej wykonuje się to od wersji Excela 2013, bo istnieją wtedy wykresy kombi, gdzie możemy łatwo kontrolować, jakiego rodzaju wykresami są poszczególne serie.

Porada 293 - Wykres slope graph 10

Porada 293 - Wykres slope graph 10b

Też musimy upewnić się, żeby nasza seria nie trafiła na oś pomocniczą.

Teraz jak zmieniliśmy typ wykresu dla serii możemy w końcu wskazać dla niej prawidłowe dane, czyli wchodzimy w polecenie Zaznacz dane z karty Projektowanie, a następnie odszukujemy naszą serię i ją Edytujemy i zaznaczamy odpowiednie zakresy danych i zatwierdzamy ją. Kolumna z 1 musi trafić na oś x. Wtedy nasza seria będzie „zaznaczać” wszystkie punkty serii z lewej strony, czyli pierwszej punkty.

Porada 293 - Wykres slope graph 11

Nawet jeśli nie korzystamy z wykresu punkowego to każda wartość wykresu ma swoją określoną pozycję na osi y i osi x. Właśnie z tej właściwości korzystamy, żeby móc szybciej dodawać inne etykiety z lewej i prawej strony serii.
Zaraz po dodaniu serii z lewej strony możemy od razu dodać serię z prawej strony, ponieważ Excel domyślne skorzysta z poprzednio dodanego typu wykresu, czyli punktowego, którego potrzebujemy, żeby oznaczyć końce serii z prawej strony (dane z kolumny C – oś y i kolumny E – oś x).

Jak mamy dodane punkty z lewej i prawej strony możemy im dodać etykiety danych (na razie zostawimy punkty, ale na koniec sprawimy, żeby były niewidoczne).

Porada 293 - Wykres slope graph 12

W etykietach danych chcemy mieć dwie wartości – nazwę serii odpowiadającą konkretnemu punktowi (nie jest to nazwa serii punktów) i wartość liczbową dla punktu. Od Excela 2013 jest to dużo prostsze, bo możemy w etykietach danych umieszczać dane z komórek – wystarczy, że zaznaczymy na etykiety danych, naciśniemy Ctrl + 1, żeby przejść do właściwości etykiet i w zakładce Opcje etykiet zaznaczyć checkbox Wartości z komórek. Wtedy otworzy się okno z polem, w którym możesz zaznaczyć zakres komórek, z którego będą pobierane wartości do etykiet osi.

Porada 293 - Wykres slope graph 13

Przed Excelem 2013 musiałbyś dla każdego punktu (etykiety) tworzyć połączoną wartość, która ma się wyświetlać w etykiecie i żeby tą połączoną wartość pobrać do konkretnej etykiety musiałbyś ją zaznaczyć, nacisnąć równa się i kliknąć na komórkę, której wartość chcesz, żeby pojawiła się w etykiecie, a na koniec zatwierdzić swój wybór Enterem. Dlatego nie miałoby sensu tworzenie tych dodatkowych serii tylko od razu dodawać i modyfikować etykiety dla pojedynczych linii.

Po dodaniu etykiet musimy jeszcze ewentualnie poszerzyć wykres i poprzesuwać trochę etykiety, żeby nie nachodziły na siebie. Od Excela 2013 możemy zmieniać rozmiar pojedynczej etykiety danych, a wcześniej jest ona mocno powiązana z rozmiarem wykresu i obszaru kreślenia.

Porada 293 - Wykres slope graph 14

Podobnie postępujemy z serią punktów po prawej stronie, czyli też dodajemy do nich etykiety, tylko przy nich potrzebujemy pobrać z Wartości komórek z kolumny F, ponieważ chcemy żeby liczba wyświetlała się bliżej linii.

Porada 293 - Wykres slope graph 15

Teraz możemy ukryć punkty, czyli zaznaczamy serię punktów, naciskamy Ctrl + 1 i we właściwościach, na zakładce Opcje znaczników, zaznaczamy pole wyboru Brak.

Porada 293 - Wykres slope graph 16

Na koniec jeszcze możemy uzupełnić nazwę naszego wykresu, a dokładniej, żeby była ona połączona z komórką A1, czyli zaznaczamy tytuł, piszemy znak równa się, klikamy komórkę A1 i zatwierdzamy nasz wybór Enterem. Uzyskujemy tytuł powiązany z wartością komórki. Podobnie jak wcześniej tworzyliśmy etykiety danych.

Porada 293 - Wykres slope graph 17

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Jak zaznaczyć urlop w kalendarzu – widzowie #116

Załóżmy, że masz kalendarz i chcesz w nim zaznaczyć dni na które przypada urlop. Kolejne urlopy mamy zapisane jako daty od do.

widzowie 116 - Jak zaznaczyć urlop w kalendarzu 01

Żeby to zrobić musimy najpierw napisać formułę, która będzie sprawdzać, czy dana data jest jednocześnie większa bądź równa dacie od i mniejsza bądź równa dacie do. Tylko nie będziemy tego robić na pojedynczych datach tylko od razu na kolumnie dat od i kolumnie dat do. Standardowo przy formatowaniu warunkowym najpierw piszemy formułę w komórkach obok, a jak ją przetestujemy to przeklejamy do formatowania warunkowego.

Czyli zaczynamy od porównania pojedynczej daty (komórka C3) z kolumną dat od:

=C3>=$AT$2:$AT$14

widzowie 116 - Jak zaznaczyć urlop w kalendarzu 02

Powyższa operacja porównania zwróci nam tablicę wartości PRAWDA i FAŁSZ. Tą operację porównania musimy połączyć jeszcze ze sprawdzeniem czy pojedyncza data (C3) jest mniejsza bądź równa od dat do (końca urlopu). Najszybciej połączymy te operacje porównania za pomocą mnożenia. Musimy tylko pamiętać o kolejności operacji dlatego operacje porównania musimy wstawić w nawiasach.

=(C3>=$AT$2:$AT$14)*(C3<=$AU$2:$AU$14)

widzowie 116 - Jak zaznaczyć urlop w kalendarzu 03

Tym razem gdybyśmy podejrzeli wynik naszej formuły to otrzymalibyśmy tablicę 0 i 1, najczęściej tylko zer. Jedynka pojawiłaby się tylko wtedy, kiedy przypadałby urlop na podstawie konkretnej pary od do.

={0;0;0;0;0;0;0;0;0;0;0;0;0}

Teraz potrzebujemy zsumować wynikową tablicę. Najlepiej to zrobić funkcją SUMA.ILOCZYNÓW – dzięki temu nie będziemy się musieli martwić, że pracujemy z formułami tablicowymi.

=SUMA.ILOCZYNÓW((C3>=$AT$2:$AT$14)*(C3<=$AU$2:$AU$14))

Po przeciągnięciu formuły w bok i dół uzyskamy 1 tam gdzie przypada urlop.

widzowie 116 - Jak zaznaczyć urlop w kalendarzu 04

Teraz wystarczy skopiować formułę do formatowania warunkowego po zakresie dat naszego kalendarza i już będę one podświetlały się ponieważ formatowanie warunkowe 0 potraktują jako wartości FAŁSZ, a 1 jako wartości PRAWDA.

widzowie 116 - Jak zaznaczyć urlop w kalendarzu 05

P.S. Jeśli nie chcesz, żeby w tym mini kalendarzu urlopy zaznaczały się podwójnie, czyli na datach, które nie przypadają na konkretny miesiąc w wierszu musisz dopisać jeszcze jeden warunek do formuły:

=SUMA.ILOCZYNÓW((C3>=$AT$2:$AT$14)*(C3<=$AU$2:$AU$14)*(MIESIĄC($B3)=MIESIĄC(C3)))

widzowie 116 - Jak zaznaczyć urlop w kalendarzu 06

Mini kalendarz w arkuszu – porada #167
https://www.youtube.com/watch?v=xfsTU4IVP_k

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Jak znaleźć przedostatni wiersz po warunku (formuła tablicowa) – widzowie #115

Czasami potrzebujemy znaleźć przedostatnią wartość na liście, a nawet przedostatnią wartość pod warunkiem. Rozpatrzmy to na prostym zestawie biegaczy i ich czasów, tylko nie chodzi nam o ich przedostatni czas w kontekście wartości, ale miejsca na naszej liście.

Widzowie 115 - Jak znaleźć przedostatni wiersz po warunku 01

W pierwszej kolejności będziemy musieli sprawdzać warunek – wykonać test logiczny, a jak wykonujemy test logiczny, to niemal nieodzowna jest funkcja JEŻELI. Właśnie w niej napiszemy nasz prosty warunek, czy pozycja na liście jest równa wybranemu przez nas biegaczowi.

=JEŻELI(A2:A21=E1

Widzowie 115 - Jak znaleźć przedostatni wiersz po warunku 02

Jeśli warunek jest spełniony to chcemy uzyskać numer wiersza danych (funkcja WIERSZ), gdzie ten warunek został spełniony. W przeciwnej sytuacji chcemy mieć zwracaną wartość FAŁSZ – wystarczy, że nie wypełnimy trzeciego argumentu funkcji JEŻELI:

=JEŻELI(A2:A21=E1;WIERSZ(A2:A21)-WIERSZ(A2)+1)

Widzowie 115 - Jak znaleźć przedostatni wiersz po warunku 03

Jeśli podejrzymy wynik formuły (klawiszem F9) to zobaczymy tablicę wartości FAŁSZ i numerów wiersza danych tam, gdzie warunek został spełniony.

{FAŁSZ;FAŁSZ;FAŁSZ;4;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ;FAŁSZ}

Nas interesuje druga maksymalna wartość, czyli potrzebujemy skorzystać z funkcji MAX.K, gdzie jej drugim argumentem będzie wartość 2.

=MAX.K(JEŻELI(A2:A21=E1;WIERSZ(A2:A21)-WIERSZ(A2)+1);2)

Widzowie 115 - Jak znaleźć przedostatni wiersz po warunku 04

Musimy tylko pamiętać zatwierdzać formułę kombinacją klawiszy Ctrl + Shift + Enter, ponieważ jest to formuła tablicowa. Uzyskujemy wtedy numer wiersza, gdzie jest interesująca nas wartość, a my potrzebujemy samej wartości. Wystarczy, że skorzystamy z funkcji INDEKS, której podamy kolumnę, z której chcemy poznać wartość.

=INDEKS($B$2:$B$21;MAX.K(JEŻELI($A$2:$A$21=E1;WIERSZ($A$2:$A$21)-1);2))

Widzowie 115 - Jak znaleźć przedostatni wiersz po warunku 05

Ciągle musimy pamiętać zatwierdzać formułę Ctrl + Shift + Enter. Analogicznie możesz budować formuły pozwalające Ci odszukać kolejne wystąpienia warunku zmieniając funkcję MAX.K na MIN.K

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP

Excel – Zamiana „angielskich” liczb na „polskie” za pomocą Tekst jako kolumny – Porada #292

W tym tygodniu na szkoleniu, które prowadziłem, został poruszony również wątek zamiany angielskiego zapisu liczb na polski za pomocą polecenia Tekst jako kolumny.
Zacznijmy od tego, ze mamy liczby, gdzie separatorem tysięcy jest przecinek, a część całkowitą od ułamkowej liczby oddziela kropka czasem też się trawi minus na końcu liczby.

Porada 292 - Zamiana angielskich liczb na polskie za pomocą Tekst jako kolumny 01

Liczby te możemy łatwo zamienić na polskie (czy też takiej jakie wynikają z Twoich ustawień regionalnych) za pomocą polecenia Tekst jako kolumny, które znajduje się na karcie Dane. Musimy tylko zaznaczyć kolumnę z liczbami, które chcemy zamienić.
Przez pierwsze dwa kroki przechodzimy szybko upewniając się tylko, że nie jest zaznaczony żaden ogranicznik, który spowodowałby podział liczby na osobne kolumny. Musimy się na chwilę zatrzymać w kroku 3 i kliknąć przycisk Zaawansowane.

Porada 292 - Zamiana angielskich liczb na polskie za pomocą Tekst jako kolumny 02

W oknie, które się otworzy musimy wybrać takie separatory jakie są w liczbach, które chcemy zmienić, a Excel zamieni je na takie, które wynikają z ustawień regionalnych. Możemy też zaznaczyć checkbox, że znak minus znajduje się na końcu liczby.

Porada 292 - Zamiana angielskich liczb na polskie za pomocą Tekst jako kolumny 03

Po tym wystarczy zatwierdzić opcje i wkleić liczby tam, gdzie chcesz np.: w kolumnę obok, żeby było widać wcześniej „angielski” zapis i aktualny „polski” zapis liczby.

Porada 292 - Zamiana angielskich liczb na polskie za pomocą Tekst jako kolumny 04

Pozdrawiam
Adam Kopeć
Miłośnik Excela
Microsoft MVP